CMake integration for Windows.
[dyninst.git] / dyninstAPI_RT / CMakeLists.txt
1 # CMake configuration for dyninstAPI_RT directory
2
3 include_directories (
4     ${PROJECT_SOURCE_DIR}/dyninstAPI_RT/src
5   )
6
7 set (SRC_LIST
8     src/RTcommon.c 
9     src/RTmemEmulator.c
10 )
11
12 if (PLATFORM MATCHES freebsd)
13 set (SRC_LIST ${SRC_LIST}
14     src/RTposix.c
15     src/RTfreebsd.c 
16     src/RTheap.c 
17     src/RTheap-freebsd.c 
18     src/RTthread.c 
19     src/RTspace.S 
20     src/RTsignal.c 
21 )
22 elseif (PLATFORM MATCHES linux OR PLATFORM MATCHES bgq)
23 set (SRC_LIST ${SRC_LIST}
24     src/RTposix.c 
25     src/RTlinux.c 
26     src/RTheap.c 
27     src/RTheap-linux.c 
28     src/RTthread.c 
29     src/RTspace.S 
30     src/RTsignal.c 
31 )
32 elseif (PLATFORM MATCHES nt OR PLATFORM MATCHES windows)
33 set (SRC_LIST ${SRC_LIST}
34     src/RTheap.c 
35     src/RTheap-win.c
36     src/RTwinnt.c
37         src/RTthread.c
38 )
39 endif ()
40
41 set (SRC_LIST_i386
42     src/RTthread-x86.c 
43     src/RTtlsgetaddr-x86.S 
44     src/RTstatic_ctors_dtors-x86.c
45 )
46 set (SRC_LIST_x86_64
47     src/RTthread-x86-64.c 
48     src/RTtlsgetaddr-x86.S
49     src/RTstatic_ctors_dtors-x86.c
50 )
51 set (SRC_LIST_ppc32
52     src/RTthread-powerpc.c
53     src/RTthread-powerpc-asm.S
54     src/RTstatic_ctors_dtors-ppc32.c
55 )
56 set (SRC_LIST_ppc64
57     src/RTthread-powerpc.c
58     src/RTthread-powerpc-asm.S
59     src/RTstatic_ctors_dtors-ppc64.c                                                                                         
60 )
61
62 # We use gcc to compile the various assembly files, but
63 # cmake doesn't default to knowing that gcc can
64 # handle .S. 
65 file (GLOB SRC_ASSEMBLY "src/*.S")
66 set_source_files_properties(${SRC_ASSEMBLY}
67         PROPERTIES
68         LANGUAGE C)
69
70 if (PLATFORM MATCHES amd64 OR PLATFORM MATCHES x86_64)
71 set (SRC_LIST_mabi ${SRC_LIST} ${SRC_LIST_i386})
72 set (SRC_LIST ${SRC_LIST} ${SRC_LIST_x86_64})
73 elseif (PLATFORM MATCHES ppc64)
74 set (SRC_LIST_mabi ${SRC_LIST} ${SRC_LIST_ppc32})
75 set (SRC_LIST ${SRC_LIST} ${SRC_LIST_ppc64}) 
76 elseif (PLATFORM MATCHES i386)
77 set (SRC_LIST ${SRC_LIST} ${SRC_LIST_i386})
78 elseif (PLATFORM MATCHES ppc32)
79 set (SRC_LIST ${SRC_LIST} ${SRC_LIST_ppc32})
80 endif()
81
82
83 add_library (dyninstAPI_RT SHARED ${SRC_LIST})
84
85 if (NOT PLATFORM MATCHES nt AND NOT PLATFORM MATCHES windows)
86     target_link_libraries (dyninstAPI_RT dl)
87 else() # windows
88     target_link_libraries (dyninstAPI_RT ws2_32 dbghelp psapi)
89 endif()
90
91 add_library (dyninstAPI_RT_static STATIC ${SRC_LIST})
92
93 set_target_properties (dyninstAPI_RT
94                       PROPERTIES
95                       SOVERSION ${SOVERSION}
96                       VERSION ${LIBVERSION})
97
98 set_target_properties (dyninstAPI_RT_static
99                       PROPERTIES
100                       OUTPUT_NAME dyninstAPI_RT
101                       SOVERSION ${SOVERSION}
102                       VERSION ${LIBVERSION})
103
104 FILE (GLOB headers "h/*.h")
105 set_target_properties (dyninstAPI_RT PROPERTIES PUBLIC_HEADER "${headers}")
106
107 INSTALL (TARGETS dyninstAPI_RT dyninstAPI_RT_static
108         EXPORT DyninstTargets
109         LIBRARY DESTINATION ${INSTALL_LIB_DIR}
110         ARCHIVE DESTINATION ${INSTALL_LIB_DIR}
111         PUBLIC_HEADER DESTINATION ${INSTALL_INCLUDE_DIR})
112
113 # Test to see if we want the 32-bit library
114
115 if (SRC_LIST_mabi) 
116
117 # The following code is from CheckCCompilerFlag.cmake. It uses a
118 # simple program that can be compiled even if 32-bit includes are 
119 # missing; we need to extend it somewhat
120
121 INCLUDE(CheckCSourceCompiles)
122
123 MACRO (CHECK_C_COMPILER_FLAG_EXTENDED _FLAG _RESULT)
124    SET(SAFE_CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
125    SET(CMAKE_C_FLAGS "${_FLAG}")
126
127 # Addition here: use signal.h
128    CHECK_C_SOURCE_COMPILES("#include <signal.h>
129    int main(void) { return 0; }" 
130         ${_RESULT}
131 # End addition
132      # Some compilers do not fail with a bad flag
133      FAIL_REGEX "warning: command line option .* is valid for .* but not for C"
134                                                             # Apple gcc
135      FAIL_REGEX "unrecognized .*option"                     # GNU
136      FAIL_REGEX "unknown .*option"                          # Clang
137      FAIL_REGEX "ignoring unknown option"                   # MSVC
138      FAIL_REGEX "warning D9002"                             # MSVC, any lang
139      FAIL_REGEX "[Uu]nknown option"                         # HP
140      FAIL_REGEX "[Ww]arning: [Oo]ption"                     # SunPro
141      FAIL_REGEX "command option .* is not recognized"       # XL
142      )
143    SET(CMAKE_C_FLAGS "${SAFE_CMAKE_C_FLAGS}")
144 ENDMACRO (CHECK_C_COMPILER_FLAG_EXTENDED)
145
146
147 message (STATUS "Checking for 32-bit runtime library...")
148
149 CHECK_C_COMPILER_FLAG_EXTENDED ("-m32" CHECK_RT_LIB_32)
150 if (CHECK_RT_LIB_32)
151 message (STATUS "Enabling 32-bit runtime library; change BUILD_RTLIB_32 to OFF to disable")
152 SET (BUILD_RTLIB_32 ON CACHE STRING "Build 32-bit version of RT library")
153 ELSE ()
154 SET (BUILD_RTLIB_32 OFF CACHE STRING "Build 32-bit version of RT library")
155 ENDIF()
156
157
158 if (BUILD_RTLIB_32 MATCHES "ON")
159
160 add_library (dyninstAPI_RT_m32 SHARED ${SRC_LIST_mabi})
161 target_link_libraries (dyninstAPI_RT_m32 dl)
162 add_library (dyninstAPI_RT_m32_static STATIC ${SRC_LIST_mabi})
163
164 set_target_properties (dyninstAPI_RT_m32
165                       PROPERTIES
166                       COMPILE_FLAGS "-m32"
167                       LINK_FLAGS "-m32"
168                       SOVERSION ${SOVERSION}
169                       VERSION ${LIBVERSION})
170
171 set_target_properties (dyninstAPI_RT_m32_static
172                       PROPERTIES
173                       OUTPUT_NAME dyninstAPI_RT_m32
174                       COMPILE_FLAGS "-m32"
175                       LINK_FLAGS "-m32"
176                       SOVERSION ${SOVERSION}
177                       VERSION ${LIBVERSION})
178
179 INSTALL (TARGETS dyninstAPI_RT_m32 dyninstAPI_RT_m32_static
180         EXPORT DyninstTargets
181         RUNTIME DESTINATION ${INSTALL_LIB_DIR}
182         LIBRARY DESTINATION ${INSTALL_LIB_DIR}
183         ARCHIVE DESTINATION ${INSTALL_LIB_DIR}
184         PUBLIC_HEADER DESTINATION ${INSTALL_INCLUDE_DIR})
185
186
187 endif()
188 endif()