Revert bad property change; add status message; use proper libdl macro
[dyninst.git] / dyninstAPI_RT / CMakeLists.txt
1 # CMake configuration for dyninstAPI_RT directory
2
3 include_directories (
4     ${PROJECT_SOURCE_DIR}/dyninstAPI_RT/src
5   )
6
7 set (SRC_LIST
8     src/RTcommon.c 
9     src/RTmemEmulator.c
10 )
11
12 if (PLATFORM MATCHES freebsd)
13 set (SRC_LIST ${SRC_LIST}
14     src/RTposix.c
15     src/RTfreebsd.c 
16     src/RTheap.c 
17     src/RTheap-freebsd.c 
18     src/RTthread.c 
19     src/RTspace.S 
20     src/RTsignal.c 
21 )
22 elseif (PLATFORM MATCHES linux OR PLATFORM MATCHES bgq)
23 set (SRC_LIST ${SRC_LIST}
24     src/RTposix.c 
25     src/RTlinux.c 
26     src/RTheap.c 
27     src/RTheap-linux.c 
28     src/RTthread.c 
29     src/RTspace.S 
30     src/RTsignal.c 
31 )
32 elseif (PLATFORM MATCHES nt OR PLATFORM MATCHES windows)
33 set (SRC_LIST ${SRC_LIST}
34     src/RTheap.c 
35     src/RTheap-win.c
36     src/RTwinnt.c
37         src/RTthread.c
38 )
39 endif ()
40
41 set (SRC_LIST_i386
42     src/RTthread-x86.c 
43     src/RTtlsgetaddr-x86.S 
44     src/RTstatic_ctors_dtors-x86.c
45 )
46 set (SRC_LIST_x86_64
47     src/RTthread-x86-64.c 
48     src/RTtlsgetaddr-x86.S
49     src/RTstatic_ctors_dtors-x86.c
50 )
51 set (SRC_LIST_ppc32
52     src/RTthread-powerpc.c
53     src/RTthread-powerpc-asm.S
54     src/RTstatic_ctors_dtors-ppc32.c
55 )
56 set (SRC_LIST_ppc64
57     src/RTthread-powerpc.c
58     src/RTthread-powerpc-asm.S
59     src/RTstatic_ctors_dtors-ppc64.c                                                                                         
60 )
61
62 # We use gcc to compile the various assembly files, but
63 # cmake doesn't default to knowing that gcc can
64 # handle .S. 
65 file (GLOB SRC_ASSEMBLY "src/*.S")
66 set_source_files_properties(${SRC_ASSEMBLY}
67         PROPERTIES
68         LANGUAGE C)
69
70 if (PLATFORM MATCHES amd64 OR PLATFORM MATCHES x86_64)
71 set (SRC_LIST_mabi ${SRC_LIST} ${SRC_LIST_i386})
72 set (SRC_LIST ${SRC_LIST} ${SRC_LIST_x86_64})
73 elseif (PLATFORM MATCHES ppc64)
74 set (SRC_LIST_mabi ${SRC_LIST} ${SRC_LIST_ppc32})
75 set (SRC_LIST ${SRC_LIST} ${SRC_LIST_ppc64}) 
76 elseif (PLATFORM MATCHES i386)
77 set (SRC_LIST ${SRC_LIST} ${SRC_LIST_i386})
78 elseif (PLATFORM MATCHES ppc32)
79 set (SRC_LIST ${SRC_LIST} ${SRC_LIST_ppc32})
80 endif()
81
82
83 add_library (dyninstAPI_RT SHARED ${SRC_LIST})
84
85 if (NOT PLATFORM MATCHES nt AND NOT PLATFORM MATCHES windows)
86     target_link_libraries (dyninstAPI_RT ${CMAKE_DL_LIBS})
87 else() # windows
88     target_link_libraries (dyninstAPI_RT ws2_32 dbghelp psapi)
89 endif()
90
91 add_library (dyninstAPI_RT_static STATIC ${SRC_LIST})
92
93 # this should carry over from CMakeLists.txt
94 set_target_properties (dyninstAPI_RT
95                       PROPERTIES
96                       SOVERSION ${SOVERSION}
97                       VERSION ${LIBVERSION})
98
99 # this will not
100 set_target_properties (dyninstAPI_RT_static
101                       PROPERTIES
102                       OUTPUT_NAME dyninstAPI_RT
103                       SOVERSION ${SOVERSION}
104                       VERSION ${LIBVERSION})
105
106 message(STATUS "dyninstAPI RT library SOVERSION: ${SOVERSION}")
107 FILE (GLOB headers "h/*.h")
108 # append, you fool!
109 set_target_properties (dyninstAPI_RT PROPERTIES PUBLIC_HEADER "${headers}")
110
111 INSTALL (TARGETS dyninstAPI_RT dyninstAPI_RT_static
112         EXPORT DyninstTargets
113         LIBRARY DESTINATION ${INSTALL_LIB_DIR}
114         ARCHIVE DESTINATION ${INSTALL_LIB_DIR}
115         PUBLIC_HEADER DESTINATION ${INSTALL_INCLUDE_DIR})
116
117 # Test to see if we want the 32-bit library
118
119 if (SRC_LIST_mabi) 
120
121 # The following code is from CheckCCompilerFlag.cmake. It uses a
122 # simple program that can be compiled even if 32-bit includes are 
123 # missing; we need to extend it somewhat
124
125 INCLUDE(CheckCSourceCompiles)
126
127 MACRO (CHECK_C_COMPILER_FLAG_EXTENDED _FLAG _RESULT)
128    SET(SAFE_CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
129    SET(CMAKE_C_FLAGS "${_FLAG}")
130
131 # Addition here: use signal.h
132    CHECK_C_SOURCE_COMPILES("#include <signal.h>
133    int main(void) { return 0; }" 
134         ${_RESULT}
135 # End addition
136      # Some compilers do not fail with a bad flag
137      FAIL_REGEX "warning: command line option .* is valid for .* but not for C"
138                                                             # Apple gcc
139      FAIL_REGEX "unrecognized .*option"                     # GNU
140      FAIL_REGEX "unknown .*option"                          # Clang
141      FAIL_REGEX "ignoring unknown option"                   # MSVC
142      FAIL_REGEX "warning D9002"                             # MSVC, any lang
143      FAIL_REGEX "[Uu]nknown option"                         # HP
144      FAIL_REGEX "[Ww]arning: [Oo]ption"                     # SunPro
145      FAIL_REGEX "command option .* is not recognized"       # XL
146      )
147    SET(CMAKE_C_FLAGS "${SAFE_CMAKE_C_FLAGS}")
148 ENDMACRO (CHECK_C_COMPILER_FLAG_EXTENDED)
149
150
151 message (STATUS "Checking for 32-bit runtime library...")
152
153 CHECK_C_COMPILER_FLAG_EXTENDED ("-m32" CHECK_RT_LIB_32)
154 if (CHECK_RT_LIB_32)
155 message (STATUS "Enabling 32-bit runtime library; change BUILD_RTLIB_32 to OFF to disable")
156 SET (BUILD_RTLIB_32 ON CACHE STRING "Build 32-bit version of RT library")
157 ELSE ()
158 SET (BUILD_RTLIB_32 OFF CACHE STRING "Build 32-bit version of RT library")
159 ENDIF()
160
161
162 if (BUILD_RTLIB_32 MATCHES "ON")
163
164 add_library (dyninstAPI_RT_m32 SHARED ${SRC_LIST_mabi})
165 target_link_libraries (dyninstAPI_RT_m32 ${CMAKE_DL_LIBS})
166 add_library (dyninstAPI_RT_m32_static STATIC ${SRC_LIST_mabi})
167
168 set_target_properties (dyninstAPI_RT_m32
169                       PROPERTIES
170                       COMPILE_FLAGS "-m32"
171                       LINK_FLAGS "-m32"
172                       SOVERSION ${SOVERSION}
173                       VERSION ${LIBVERSION})
174
175 set_target_properties (dyninstAPI_RT_m32_static
176                       PROPERTIES
177                       OUTPUT_NAME dyninstAPI_RT_m32
178                       COMPILE_FLAGS "-m32"
179                       LINK_FLAGS "-m32"
180                       SOVERSION ${SOVERSION}
181                       VERSION ${LIBVERSION})
182
183 INSTALL (TARGETS dyninstAPI_RT_m32 dyninstAPI_RT_m32_static
184         EXPORT DyninstTargets
185         RUNTIME DESTINATION ${INSTALL_LIB_DIR}
186         LIBRARY DESTINATION ${INSTALL_LIB_DIR}
187         ARCHIVE DESTINATION ${INSTALL_LIB_DIR}
188         PUBLIC_HEADER DESTINATION ${INSTALL_INCLUDE_DIR})
189
190
191 endif()
192 endif()