CMake fixes for building/installing components separately.
[dyninst.git] / dyninstAPI_RT / CMakeLists.txt
1 # CMake configuration for dyninstAPI_RT directory
2 cmake_minimum_required (VERSION 2.6.4)
3 project (DyninstRT C)
4
5 set (DYNINST_ROOT ${PROJECT_SOURCE_DIR}/..)
6
7 include (${DYNINST_ROOT}/cmake/shared.cmake)
8
9 include_directories (
10     ${DYNINST_ROOT}/dyninstAPI_RT/src
11     ${DYNINST_ROOT}/dyninstAPI_RT/h
12     ${DYNINST_ROOT}
13   )
14
15 set (SRC_LIST
16     src/RTcommon.c 
17     src/RTmemEmulator.c
18 )
19
20 if (PLATFORM MATCHES freebsd)
21 set (SRC_LIST ${SRC_LIST}
22     src/RTposix.c
23     src/RTfreebsd.c 
24     src/RTheap.c 
25     src/RTheap-freebsd.c 
26     src/RTthread.c 
27     src/RTspace.S 
28     src/RTsignal.c 
29 )
30 elseif (PLATFORM MATCHES linux OR PLATFORM MATCHES bgq)
31 set (SRC_LIST ${SRC_LIST}
32     src/RTposix.c 
33     src/RTlinux.c 
34     src/RTheap.c 
35     src/RTheap-linux.c 
36     src/RTthread.c 
37     src/RTspace.S 
38     src/RTsignal.c
39     src/RTstatic_ctors_dtors_begin.c 
40     src/RTstatic_ctors_dtors_end.c 
41 )
42 elseif (PLATFORM MATCHES nt OR PLATFORM MATCHES windows)
43 set (SRC_LIST ${SRC_LIST}
44     src/RTheap.c 
45     src/RTheap-win.c
46     src/RTwinnt.c
47     src/RTthread.c
48     src/RTthread-x86.c
49 )
50 endif ()
51
52 set (SRC_LIST_i386
53     src/RTthread-x86.c 
54     src/RTtlsgetaddr-x86.S 
55     src/RTstatic_ctors_dtors-x86.c
56 )
57 set (SRC_LIST_x86_64
58     src/RTthread-x86-64.c 
59     src/RTtlsgetaddr-x86.S
60     src/RTstatic_ctors_dtors-x86.c
61 )
62 set (SRC_LIST_ppc32
63     src/RTthread-powerpc.c
64     src/RTthread-powerpc-asm.S
65     src/RTstatic_ctors_dtors-ppc32.c
66 )
67 set (SRC_LIST_ppc64
68     src/RTthread-powerpc.c
69     src/RTthread-powerpc-asm.S
70     src/RTstatic_ctors_dtors-ppc64.c                                                                                         
71 )
72
73
74 # We use gcc to compile the various assembly files, but
75 # cmake doesn't default to knowing that gcc can
76 # handle .S. 
77 ENABLE_LANGUAGE(ASM)
78 file (GLOB SRC_ASSEMBLY "src/*.S")
79 if(PLATFORM MATCHES bgq OR NEED_NATIVE_ASSEMBER MATCHES YES)
80 set_source_files_properties(${SRC_ASSEMBLY}
81         PROPERTIES
82         LANGUAGE ASM)
83 else()
84 set_source_files_properties(${SRC_ASSEMBLY}
85         PROPERTIES
86         LANGUAGE C)
87 endif()
88
89 # The arch-specific files other than RTthread-x86 are Unix-only.
90 if(UNIX)
91 if (PLATFORM MATCHES amd64 OR PLATFORM MATCHES x86_64)
92 set (SRC_LIST_mabi ${SRC_LIST} ${SRC_LIST_i386})
93 set (SRC_LIST ${SRC_LIST} ${SRC_LIST_x86_64})
94 elseif (PLATFORM MATCHES ppc64)
95 set (SRC_LIST_mabi ${SRC_LIST} ${SRC_LIST_ppc32})
96 set (SRC_LIST ${SRC_LIST} ${SRC_LIST_ppc64}) 
97 elseif (PLATFORM MATCHES i386)
98 set (SRC_LIST ${SRC_LIST} ${SRC_LIST_i386})
99 elseif (PLATFORM MATCHES ppc32)
100 set (SRC_LIST ${SRC_LIST} ${SRC_LIST_ppc32})
101 endif()
102 endif()
103
104 add_library (dyninstAPI_RT SHARED ${SRC_LIST})
105
106 if (NOT PLATFORM MATCHES nt AND NOT PLATFORM MATCHES windows)
107     target_link_libraries (dyninstAPI_RT ${CMAKE_DL_LIBS})
108 else() # windows
109     target_link_libraries (dyninstAPI_RT ws2_32 dbghelp psapi)
110 endif()
111
112 add_library (dyninstAPI_RT_static STATIC ${SRC_LIST})
113
114 # this should carry over from CMakeLists.txt
115 set_target_properties (dyninstAPI_RT
116                       PROPERTIES
117                       OUTPUT_NAME dyninstAPI_RT
118                       SOVERSION ${SOVERSION}
119                       VERSION ${LIBVERSION})
120
121 # this will not
122 set_target_properties (dyninstAPI_RT_static
123                       PROPERTIES
124                       OUTPUT_NAME dyninstAPI_RT
125                       COMPILE_DEFINITIONS DYNINST_RT_STATIC_LIB)
126
127 set_target_properties (dyninstAPI_RT PROPERTIES CLEAN_DIRECT_OUTPUT 1)
128 set_target_properties (dyninstAPI_RT_static PROPERTIES CLEAN_DIRECT_OUTPUT 1)
129
130
131 message(STATUS "dyninstAPI RT library SOVERSION: ${SOVERSION}")
132 message(STATUS "dyninstAPI RT library LIBVERSION: ${LIBVERSION}")
133
134 get_property(dyninstAPI_RT_location TARGET dyninstAPI_RT PROPERTY LOCATION)
135 message(STATUS "dyninstAPI output location: ${dyninstAPI_RT_location}")
136
137 FILE (GLOB headers "h/*.h")
138 # append, you fool!
139 set_target_properties (dyninstAPI_RT dyninstAPI_RT_static PROPERTIES PUBLIC_HEADER "${headers}")
140
141 INSTALL (TARGETS dyninstAPI_RT dyninstAPI_RT_static
142         EXPORT DyninstTargets
143         RUNTIME DESTINATION ${INSTALL_LIB_DIR}
144         LIBRARY DESTINATION ${INSTALL_LIB_DIR}
145         ARCHIVE DESTINATION ${INSTALL_LIB_DIR}
146         PUBLIC_HEADER DESTINATION ${INSTALL_INCLUDE_DIR})
147
148 # Test to see if we want the 32-bit library
149
150 if (SRC_LIST_mabi) 
151
152 # The following code is from CheckCCompilerFlag.cmake. It uses a
153 # simple program that can be compiled even if 32-bit includes are 
154 # missing; we need to extend it somewhat
155
156 INCLUDE(CheckCSourceCompiles)
157
158 MACRO (CHECK_C_COMPILER_FLAG_EXTENDED _FLAG _RESULT)
159    SET(SAFE_CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
160    SET(CMAKE_C_FLAGS "${_FLAG}")
161
162 # Addition here: use signal.h
163    CHECK_C_SOURCE_COMPILES("#include <signal.h>
164    int main(void) { return 0; }" 
165         ${_RESULT}
166 # End addition
167      # Some compilers do not fail with a bad flag
168      FAIL_REGEX "warning: command line option .* is valid for .* but not for C"
169                                                             # Apple gcc
170      FAIL_REGEX "unrecognized .*option"                     # GNU
171      FAIL_REGEX "unknown .*option"                          # Clang
172      FAIL_REGEX "ignoring unknown option"                   # MSVC
173      FAIL_REGEX "warning D9002"                             # MSVC, any lang
174      FAIL_REGEX "[Uu]nknown option"                         # HP
175      FAIL_REGEX "[Ww]arning: [Oo]ption"                     # SunPro
176      FAIL_REGEX "command option .* is not recognized"       # XL
177      )
178    SET(CMAKE_C_FLAGS "${SAFE_CMAKE_C_FLAGS}")
179 ENDMACRO (CHECK_C_COMPILER_FLAG_EXTENDED)
180
181
182 message (STATUS "Checking for 32-bit runtime library...")
183
184 CHECK_C_COMPILER_FLAG_EXTENDED ("-m32" CHECK_RT_LIB_32)
185 if (CHECK_RT_LIB_32 AND NOT ${PLATFORM} MATCHES bgq AND NOT ${BUILD_RTLIB_32} MATCHES "OFF")
186 message (STATUS "Enabling 32-bit runtime library; change BUILD_RTLIB_32 to OFF to disable")
187 SET (BUILD_RTLIB_32 ON)
188 ELSE ()
189 message (STATUS "Disabling 32-bit runtime library; change BUILD_RTLIB_32 to ON and install 32-bit build environment to enable")
190 SET (BUILD_RTLIB_32 OFF)
191 ENDIF()
192
193 if (BUILD_RTLIB_32 MATCHES "ON")
194
195 add_library (dyninstAPI_RT_m32 SHARED ${SRC_LIST_mabi})
196 target_link_libraries (dyninstAPI_RT_m32 ${CMAKE_DL_LIBS})
197 add_library (dyninstAPI_RT_m32_static STATIC ${SRC_LIST_mabi})
198
199 set_target_properties (dyninstAPI_RT_m32
200                       PROPERTIES
201                       COMPILE_FLAGS "-DMUTATEE_32 -m32"
202                       LINK_FLAGS "-m32"
203                       OUTPUT_NAME dyninstAPI_RT_m32
204                       SOVERSION ${SOVERSION}
205                       VERSION ${LIBVERSION})
206
207 set_target_properties (dyninstAPI_RT_m32_static
208                       PROPERTIES
209                       OUTPUT_NAME dyninstAPI_RT_m32
210                       COMPILE_FLAGS "-DMUTATEE_32 -m32"
211                       LINK_FLAGS "-m32"
212                       COMPILE_DEFINITIONS DYNINST_RT_STATIC_LIB)
213
214 set_target_properties (dyninstAPI_RT_m32 PROPERTIES CLEAN_DIRECT_OUTPUT 1)
215 set_target_properties (dyninstAPI_RT_m32_static PROPERTIES CLEAN_DIRECT_OUTPUT 1)
216
217 INSTALL (TARGETS dyninstAPI_RT_m32 dyninstAPI_RT_m32_static
218         EXPORT DyninstTargets
219         RUNTIME DESTINATION ${INSTALL_LIB_DIR}
220         LIBRARY DESTINATION ${INSTALL_LIB_DIR}
221         ARCHIVE DESTINATION ${INSTALL_LIB_DIR}
222         PUBLIC_HEADER DESTINATION ${INSTALL_INCLUDE_DIR})
223
224 install (EXPORT DyninstTargets
225   DESTINATION "${INSTALL_CMAKE_DIR}")
226
227 endif()
228 endif()