Fixes for three bugs: tie CMake version dependency to use of the relevant features...
[dyninst.git] / dyninstAPI_RT / CMakeLists.txt
1 # CMake configuration for dyninstAPI_RT directory
2 cmake_minimum_required (VERSION 2.6.4)
3 project (DyninstRT)
4
5 set (DYNINST_ROOT ${PROJECT_SOURCE_DIR}/..)
6
7 include (${DYNINST_ROOT}/cmake/shared.cmake)
8
9 include_directories (
10     ${DYNINST_ROOT}/dyninstAPI_RT/src
11     ${DYNINST_ROOT}/dyninstAPI_RT/h
12     ${DYNINST_ROOT}
13   )
14
15 set (SRC_LIST
16     src/RTcommon.c 
17     src/RTmemEmulator.c
18 )
19
20 if (PLATFORM MATCHES freebsd)
21 set (SRC_LIST ${SRC_LIST}
22     src/RTposix.c
23     src/RTfreebsd.c 
24     src/RTheap.c 
25     src/RTheap-freebsd.c 
26     src/RTthread.c 
27     src/RTspace.S 
28     src/RTsignal.c 
29 )
30 elseif (PLATFORM MATCHES linux OR PLATFORM MATCHES bgq)
31 set (SRC_LIST ${SRC_LIST}
32     src/RTposix.c 
33     src/RTlinux.c 
34     src/RTheap.c 
35     src/RTheap-linux.c 
36     src/RTthread.c 
37     src/RTspace.S 
38     src/RTsignal.c
39     src/RTstatic_ctors_dtors_begin.c 
40     src/RTstatic_ctors_dtors_end.c 
41 )
42 elseif (PLATFORM MATCHES nt OR PLATFORM MATCHES windows)
43 set (SRC_LIST ${SRC_LIST}
44     src/RTheap.c 
45     src/RTheap-win.c
46     src/RTwinnt.c
47     src/RTthread.c
48     src/RTthread-x86.c
49 )
50 endif ()
51
52 set (SRC_LIST_i386
53     src/RTthread-x86.c 
54     src/RTtlsgetaddr-x86.S 
55     src/RTstatic_ctors_dtors-x86.c
56 )
57 set (SRC_LIST_x86_64
58     src/RTthread-x86-64.c 
59     src/RTtlsgetaddr-x86.S
60     src/RTstatic_ctors_dtors-x86.c
61 )
62 set (SRC_LIST_ppc32
63     src/RTthread-powerpc.c
64     src/RTthread-powerpc-asm.S
65     src/RTstatic_ctors_dtors-ppc32.c
66 )
67 set (SRC_LIST_ppc64
68     src/RTthread-powerpc.c
69     src/RTthread-powerpc-asm.S
70     src/RTstatic_ctors_dtors-ppc64.c                                                                                         
71 )
72
73
74 # We use gcc to compile the various assembly files, but
75 # cmake doesn't default to knowing that gcc can
76 # handle .S. 
77 file (GLOB SRC_ASSEMBLY "src/*.S")
78 set_source_files_properties(${SRC_ASSEMBLY}
79         PROPERTIES
80         LANGUAGE C)
81
82 # The arch-specific files other than RTthread-x86 are Unix-only.
83 if(UNIX)
84 if (PLATFORM MATCHES amd64 OR PLATFORM MATCHES x86_64)
85 set (SRC_LIST_mabi ${SRC_LIST} ${SRC_LIST_i386})
86 set (SRC_LIST ${SRC_LIST} ${SRC_LIST_x86_64})
87 elseif (PLATFORM MATCHES ppc64)
88 set (SRC_LIST_mabi ${SRC_LIST} ${SRC_LIST_ppc32})
89 set (SRC_LIST ${SRC_LIST} ${SRC_LIST_ppc64}) 
90 elseif (PLATFORM MATCHES i386)
91 set (SRC_LIST ${SRC_LIST} ${SRC_LIST_i386})
92 elseif (PLATFORM MATCHES ppc32)
93 set (SRC_LIST ${SRC_LIST} ${SRC_LIST_ppc32})
94 endif()
95 endif()
96
97 add_library (dyninstAPI_RT SHARED ${SRC_LIST})
98
99 if (NOT PLATFORM MATCHES nt AND NOT PLATFORM MATCHES windows)
100     target_link_libraries (dyninstAPI_RT ${CMAKE_DL_LIBS})
101 else() # windows
102     target_link_libraries (dyninstAPI_RT ws2_32 dbghelp psapi)
103 endif()
104
105 add_library (dyninstAPI_RT_static STATIC ${SRC_LIST})
106
107 # this should carry over from CMakeLists.txt
108 set_target_properties (dyninstAPI_RT dyninstAPI_RT_static
109                       PROPERTIES
110                       SOVERSION ${SOVERSION}
111                       VERSION ${LIBVERSION})
112
113 # this will not
114 set_target_properties (dyninstAPI_RT_static
115                       PROPERTIES
116                       OUTPUT_NAME dyninstAPI_RT
117                       COMPILE_DEFINITIONS DYNINST_RT_STATIC_LIB)
118
119 message(STATUS "dyninstAPI RT library SOVERSION: ${SOVERSION}")
120 message(STATUS "dyninstAPI RT library LIBVERSION: ${LIBVERSION}")
121
122 get_property(dyninstAPI_RT_location TARGET dyninstAPI_RT PROPERTY LOCATION)
123 message(STATUS "dyninstAPI output location: ${dyninstAPI_RT_location}")
124
125 FILE (GLOB headers "h/*.h")
126 # append, you fool!
127 set_target_properties (dyninstAPI_RT dyninstAPI_RT_static PROPERTIES PUBLIC_HEADER "${headers}")
128
129 INSTALL (TARGETS dyninstAPI_RT dyninstAPI_RT_static
130         EXPORT DyninstTargets
131         RUNTIME DESTINATION ${INSTALL_LIB_DIR}
132         LIBRARY DESTINATION ${INSTALL_LIB_DIR}
133         ARCHIVE DESTINATION ${INSTALL_LIB_DIR}
134         PUBLIC_HEADER DESTINATION ${INSTALL_INCLUDE_DIR})
135
136 # Test to see if we want the 32-bit library
137
138 if (SRC_LIST_mabi) 
139
140 # The following code is from CheckCCompilerFlag.cmake. It uses a
141 # simple program that can be compiled even if 32-bit includes are 
142 # missing; we need to extend it somewhat
143
144 INCLUDE(CheckCSourceCompiles)
145
146 MACRO (CHECK_C_COMPILER_FLAG_EXTENDED _FLAG _RESULT)
147    SET(SAFE_CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
148    SET(CMAKE_C_FLAGS "${_FLAG}")
149
150 # Addition here: use signal.h
151    CHECK_C_SOURCE_COMPILES("#include <signal.h>
152    int main(void) { return 0; }" 
153         ${_RESULT}
154 # End addition
155      # Some compilers do not fail with a bad flag
156      FAIL_REGEX "warning: command line option .* is valid for .* but not for C"
157                                                             # Apple gcc
158      FAIL_REGEX "unrecognized .*option"                     # GNU
159      FAIL_REGEX "unknown .*option"                          # Clang
160      FAIL_REGEX "ignoring unknown option"                   # MSVC
161      FAIL_REGEX "warning D9002"                             # MSVC, any lang
162      FAIL_REGEX "[Uu]nknown option"                         # HP
163      FAIL_REGEX "[Ww]arning: [Oo]ption"                     # SunPro
164      FAIL_REGEX "command option .* is not recognized"       # XL
165      )
166    SET(CMAKE_C_FLAGS "${SAFE_CMAKE_C_FLAGS}")
167 ENDMACRO (CHECK_C_COMPILER_FLAG_EXTENDED)
168
169
170 message (STATUS "Checking for 32-bit runtime library...")
171
172 CHECK_C_COMPILER_FLAG_EXTENDED ("-m32" CHECK_RT_LIB_32)
173 if (CHECK_RT_LIB_32 AND NOT ${PLATFORM} MATCHES bgq)
174 message (STATUS "Enabling 32-bit runtime library; change BUILD_RTLIB_32 to OFF to disable")
175 SET (BUILD_RTLIB_32 ON CACHE STRING "Build 32-bit version of RT library")
176 ELSE ()
177 SET (BUILD_RTLIB_32 OFF CACHE STRING "Build 32-bit version of RT library")
178 ENDIF()
179
180
181 if (BUILD_RTLIB_32 MATCHES "ON")
182
183 add_library (dyninstAPI_RT_m32 SHARED ${SRC_LIST_mabi})
184 target_link_libraries (dyninstAPI_RT_m32 ${CMAKE_DL_LIBS})
185 add_library (dyninstAPI_RT_m32_static STATIC ${SRC_LIST_mabi})
186
187 set_target_properties (dyninstAPI_RT_m32 dyninstAPI_RT_m32_static
188                       PROPERTIES
189                       COMPILE_FLAGS "-DMUTATEE_32 -m32"
190                       LINK_FLAGS "-m32"
191                       SOVERSION ${SOVERSION}
192                       VERSION ${LIBVERSION})
193
194 set_target_properties (dyninstAPI_RT_m32_static
195                       PROPERTIES
196                       OUTPUT_NAME dyninstAPI_RT_m32
197                       COMPILE_FLAGS "-DMUTATEE_32 -m32"
198                       LINK_FLAGS "-m32"
199                       COMPILE_DEFINITIONS DYNINST_RT_STATIC_LIB)
200 #                      SOVERSION ${SOVERSION}
201 #                      VERSION ${LIBVERSION})
202
203 INSTALL (TARGETS dyninstAPI_RT_m32 dyninstAPI_RT_m32_static
204         EXPORT DyninstTargets
205         RUNTIME DESTINATION ${INSTALL_LIB_DIR}
206         LIBRARY DESTINATION ${INSTALL_LIB_DIR}
207         ARCHIVE DESTINATION ${INSTALL_LIB_DIR}
208         PUBLIC_HEADER DESTINATION ${INSTALL_INCLUDE_DIR})
209
210
211 endif()
212 endif()