Fix typo in i386 build
[dyninst.git] / autodyninst / boost.m4
1 # boost.m4: Locate Boost headers and libraries for autoconf-based projects.
2 # Copyright (C) 2007, 2008, 2009, 2010, 2011  Benoit Sigoure <tsuna@lrde.epita.fr>
3 #
4 # This program is free software: you can redistribute it and/or modify
5 # it under the terms of the GNU General Public License as published by
6 # the Free Software Foundation, either version 3 of the License, or
7 # (at your option) any later version.
8 #
9 # Additional permission under section 7 of the GNU General Public
10 # License, version 3 ("GPLv3"):
11 #
12 # If you convey this file as part of a work that contains a
13 # configuration script generated by Autoconf, you may do so under
14 # terms of your choice.
15 #
16 # This program is distributed in the hope that it will be useful,
17 # but WITHOUT ANY WARRANTY; without even the implied warranty of
18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
19 # GNU General Public License for more details.
20 #
21 # You should have received a copy of the GNU General Public License
22 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
23
24 m4_define([_BOOST_SERIAL], [m4_translit([
25 # serial 16
26 ], [#
27 ], [])])
28
29 # Original sources can be found at http://github.com/tsuna/boost.m4
30 # You can fetch the latest version of the script by doing:
31 #   wget http://github.com/tsuna/boost.m4/raw/master/build-aux/boost.m4
32
33 # ------ #
34 # README #
35 # ------ #
36
37 # This file provides several macros to use the various Boost libraries.
38 # The first macro is BOOST_REQUIRE.  It will simply check if it's possible to
39 # find the Boost headers of a given (optional) minimum version and it will
40 # define BOOST_CPPFLAGS accordingly.  It will add an option --with-boost to
41 # your configure so that users can specify non standard locations.
42 # If the user's environment contains BOOST_ROOT and --with-boost was not
43 # specified, --with-boost=$BOOST_ROOT is implicitly used.
44 # For more README and documentation, go to http://github.com/tsuna/boost.m4
45 # Note: THESE MACROS ASSUME THAT YOU USE LIBTOOL.  If you don't, don't worry,
46 # simply read the README, it will show you what to do step by step.
47
48 m4_pattern_forbid([^_?(BOOST|Boost)_])
49
50
51 # _BOOST_SED_CPP(SED-PROGRAM, PROGRAM,
52 #                [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
53 # --------------------------------------------------------
54 # Same as AC_EGREP_CPP, but leave the result in conftest.i.
55 #
56 # SED-PROGRAM is *not* overquoted, as in AC_EGREP_CPP.  It is expanded
57 # in double-quotes, so escape your double quotes.
58 #
59 # It could be useful to turn this into a macro which extracts the
60 # value of any macro.
61 m4_define([_BOOST_SED_CPP],
62 [AC_LANG_PREPROC_REQUIRE()dnl
63 AC_REQUIRE([AC_PROG_SED])dnl
64 AC_LANG_CONFTEST([AC_LANG_SOURCE([[$2]])])
65 AS_IF([dnl eval is necessary to expand ac_cpp.
66 dnl Ultrix and Pyramid sh refuse to redirect output of eval, so use subshell.
67 dnl Beware of Windows end-of-lines, for instance if we are running
68 dnl some Windows programs under Wine.  In that case, boost/version.hpp
69 dnl is certainly using "\r\n", but the regular Unix shell will only
70 dnl strip `\n' with backquotes, not the `\r'.  This results in
71 dnl boost_cv_lib_version='1_37\r' for instance, which breaks
72 dnl everything else.
73 dnl Cannot use 'dnl' after [$4] because a trailing dnl may break AC_CACHE_CHECK
74 (eval "$ac_cpp conftest.$ac_ext") 2>&AS_MESSAGE_LOG_FD |
75   tr -d '\r' |
76   $SED -n -e "$1" >conftest.i 2>&1],
77   [$3],
78   [$4])
79 rm -rf conftest*
80 ])# AC_EGREP_CPP
81
82
83
84 # BOOST_REQUIRE([VERSION], [ACTION-IF-NOT-FOUND])
85 # -----------------------------------------------
86 # Look for Boost.  If version is given, it must either be a literal of the form
87 # "X.Y.Z" where X, Y and Z are integers (the ".Z" part being optional) or a
88 # variable "$var".
89 # Defines the value BOOST_CPPFLAGS.  This macro only checks for headers with
90 # the required version, it does not check for any of the Boost libraries.
91 # On # success, defines HAVE_BOOST.  On failure, calls the optional
92 # ACTION-IF-NOT-FOUND action if one was supplied.
93 # Otherwise aborts with an error message.
94 AC_DEFUN([BOOST_REQUIRE],
95 [AC_REQUIRE([AC_PROG_CXX])dnl
96 AC_REQUIRE([AC_PROG_GREP])dnl
97 echo "$as_me: this is boost.m4[]_BOOST_SERIAL" >&AS_MESSAGE_LOG_FD
98 boost_save_IFS=$IFS
99 boost_version_req=$1
100 IFS=.
101 set x $boost_version_req 0 0 0
102 IFS=$boost_save_IFS
103 shift
104 boost_version_req=`expr "$[1]" '*' 100000 + "$[2]" '*' 100 + "$[3]"`
105 boost_version_req_string=$[1].$[2].$[3]
106 AC_ARG_WITH([boost],
107    [AS_HELP_STRING([--with-boost=DIR],
108                    [prefix of Boost $1 @<:@guess@:>@])])dnl
109 AC_ARG_VAR([BOOST_ROOT],[Location of Boost installation])dnl
110 # If BOOST_ROOT is set and the user has not provided a value to
111 # --with-boost, then treat BOOST_ROOT as if it the user supplied it.
112 if test x"$BOOST_ROOT" != x; then
113   if test x"$with_boost" = x; then
114     AC_MSG_NOTICE([Detected BOOST_ROOT; continuing with --with-boost=$BOOST_ROOT])
115     with_boost=$BOOST_ROOT
116   else
117     AC_MSG_NOTICE([Detected BOOST_ROOT=$BOOST_ROOT, but overridden by --with-boost=$with_boost])
118   fi
119 fi
120 AC_SUBST([DISTCHECK_CONFIGURE_FLAGS],
121          ["$DISTCHECK_CONFIGURE_FLAGS '--with-boost=$with_boost'"])dnl
122 boost_save_CPPFLAGS=$CPPFLAGS
123   AC_CACHE_CHECK([for Boost headers version >= $boost_version_req_string],
124     [boost_cv_inc_path],
125     [boost_cv_inc_path=no
126 AC_LANG_PUSH([C++])dnl
127 m4_pattern_allow([^BOOST_VERSION$])dnl
128     AC_LANG_CONFTEST([AC_LANG_PROGRAM([[#include <boost/version.hpp>
129 #if !defined BOOST_VERSION
130 # error BOOST_VERSION is not defined
131 #elif BOOST_VERSION < $boost_version_req
132 # error Boost headers version < $boost_version_req
133 #endif
134 ]])])
135     # If the user provided a value to --with-boost, use it and only it.
136     case $with_boost in #(
137       ''|yes) set x '' /opt/local/include /usr/local/include /opt/include \
138                  /usr/include C:/Boost/include;; #(
139       *)      set x "$with_boost/include" "$with_boost";;
140     esac
141     shift
142     for boost_dir
143     do
144     # Without --layout=system, Boost (or at least some versions) installs
145     # itself in <prefix>/include/boost-<version>.  This inner loop helps to
146     # find headers in such directories.
147     #
148     # Any ${boost_dir}/boost-x_xx directories are searched in reverse version
149     # order followed by ${boost_dir}.  The final '.' is a sentinel for
150     # searching $boost_dir" itself.  Entries are whitespace separated.
151     #
152     # I didn't indent this loop on purpose (to avoid over-indented code)
153     boost_layout_system_search_list=`cd "$boost_dir" 2>/dev/null \
154         && ls -1 | "${GREP}" '^boost-' | sort -rn -t- -k2 \
155         && echo .`
156     for boost_inc in $boost_layout_system_search_list
157     do
158       if test x"$boost_inc" != x.; then
159         boost_inc="$boost_dir/$boost_inc"
160       else
161         boost_inc="$boost_dir" # Uses sentinel in boost_layout_system_search_list
162       fi
163       if test x"$boost_inc" != x; then
164         # We are going to check whether the version of Boost installed
165         # in $boost_inc is usable by running a compilation that
166         # #includes it.  But if we pass a -I/some/path in which Boost
167         # is not installed, the compiler will just skip this -I and
168         # use other locations (either from CPPFLAGS, or from its list
169         # of system include directories).  As a result we would use
170         # header installed on the machine instead of the /some/path
171         # specified by the user.  So in that precise case (trying
172         # $boost_inc), make sure the version.hpp exists.
173         #
174         # Use test -e as there can be symlinks.
175         test -e "$boost_inc/boost/version.hpp" || continue
176         CPPFLAGS="$CPPFLAGS -I$boost_inc"
177       fi
178       AC_COMPILE_IFELSE([], [boost_cv_inc_path=yes], [boost_cv_version=no])
179       if test x"$boost_cv_inc_path" = xyes; then
180         if test x"$boost_inc" != x; then
181           boost_cv_inc_path=$boost_inc
182         fi
183         break 2
184       fi
185     done
186     done
187 AC_LANG_POP([C++])dnl
188     ])
189     case $boost_cv_inc_path in #(
190       no)
191         boost_errmsg="cannot find Boost headers version >= $boost_version_req_string"
192         m4_if([$2], [],  [AC_MSG_ERROR([$boost_errmsg])],
193                         [AC_MSG_NOTICE([$boost_errmsg])])
194         $2
195         ;;#(
196       yes)
197         BOOST_CPPFLAGS=
198         ;;#(
199       *)
200         AC_SUBST([BOOST_CPPFLAGS], ["-I$boost_cv_inc_path"])dnl
201         ;;
202     esac
203   if test x"$boost_cv_inc_path" != xno; then
204   AC_DEFINE([HAVE_BOOST], [1],
205             [Defined if the requested minimum BOOST version is satisfied])
206   AC_CACHE_CHECK([for Boost's header version],
207     [boost_cv_lib_version],
208     [m4_pattern_allow([^BOOST_LIB_VERSION$])dnl
209      _BOOST_SED_CPP([/^boost-lib-version = /{s///;s/\"//g;p;q;}],
210                     [#include <boost/version.hpp>
211 boost-lib-version = BOOST_LIB_VERSION],
212     [boost_cv_lib_version=`cat conftest.i`])])
213     # e.g. "134" for 1_34_1 or "135" for 1_35
214     boost_major_version=`echo "$boost_cv_lib_version" | sed 's/_//;s/_.*//'`
215     case $boost_major_version in #(
216       '' | *[[!0-9]]*)
217         AC_MSG_ERROR([invalid value: boost_major_version=$boost_major_version])
218         ;;
219     esac
220 fi
221 CPPFLAGS=$boost_save_CPPFLAGS
222 ])# BOOST_REQUIRE
223
224 # BOOST_STATIC()
225 # --------------
226 # Add the "--enable-static-boost" configure argument. If this argument is given
227 # on the command line, static versions of the libraries will be looked up.
228 AC_DEFUN([BOOST_STATIC],
229   [AC_ARG_ENABLE([static-boost],
230      [AC_HELP_STRING([--enable-static-boost],
231                [Prefer the static boost libraries over the shared ones [no]])],
232      [enable_static_boost=yes],
233      [enable_static_boost=no])])# BOOST_STATIC
234
235 # BOOST_FIND_HEADER([HEADER-NAME], [ACTION-IF-NOT-FOUND], [ACTION-IF-FOUND])
236 # --------------------------------------------------------------------------
237 # Wrapper around AC_CHECK_HEADER for Boost headers.  Useful to check for
238 # some parts of the Boost library which are only made of headers and don't
239 # require linking (such as Boost.Foreach).
240 #
241 # Default ACTION-IF-NOT-FOUND: Fail with a fatal error unless Boost couldn't be
242 # found in the first place, in which case by default a notice is issued to the
243 # user.  Presumably if we haven't died already it's because it's OK to not have
244 # Boost, which is why only a notice is issued instead of a hard error.
245 #
246 # Default ACTION-IF-FOUND: define the preprocessor symbol HAVE_<HEADER-NAME> in
247 # case of success # (where HEADER-NAME is written LIKE_THIS, e.g.,
248 # HAVE_BOOST_FOREACH_HPP).
249 AC_DEFUN([BOOST_FIND_HEADER],
250 [AC_REQUIRE([BOOST_REQUIRE])dnl
251 if test x"$boost_cv_inc_path" = xno; then
252   m4_default([$2], [AC_MSG_NOTICE([Boost not available, not searching for $1])])
253 else
254 AC_LANG_PUSH([C++])dnl
255 boost_save_CPPFLAGS=$CPPFLAGS
256 CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
257 AC_CHECK_HEADER([$1],
258   [m4_default([$3], [AC_DEFINE(AS_TR_CPP([HAVE_$1]), [1],
259                                [Define to 1 if you have <$1>])])],
260   [m4_default([$2], [AC_MSG_ERROR([cannot find $1])])])
261 CPPFLAGS=$boost_save_CPPFLAGS
262 AC_LANG_POP([C++])dnl
263 fi
264 ])# BOOST_FIND_HEADER
265
266
267 # BOOST_FIND_LIB([LIB-NAME], [PREFERRED-RT-OPT], [HEADER-NAME], [CXX-TEST],
268 #                [CXX-PROLOGUE])
269 # -------------------------------------------------------------------------
270 # Look for the Boost library LIB-NAME (e.g., LIB-NAME = `thread', for
271 # libboost_thread).  Check that HEADER-NAME works and check that
272 # libboost_LIB-NAME can link with the code CXX-TEST.  The optional argument
273 # CXX-PROLOGUE can be used to include some C++ code before the `main'
274 # function.
275 #
276 # Invokes BOOST_FIND_HEADER([HEADER-NAME]) (see above).
277 #
278 # Boost libraries typically come compiled with several flavors (with different
279 # runtime options) so PREFERRED-RT-OPT is the preferred suffix.  A suffix is one
280 # or more of the following letters: sgdpn (in that order).  s = static
281 # runtime, d = debug build, g = debug/diagnostic runtime, p = STLPort build,
282 # n = (unsure) STLPort build without iostreams from STLPort (it looks like `n'
283 # must always be used along with `p').  Additionally, PREFERRED-RT-OPT can
284 # start with `mt-' to indicate that there is a preference for multi-thread
285 # builds.  Some sample values for PREFERRED-RT-OPT: (nothing), mt, d, mt-d, gdp
286 # ...  If you want to make sure you have a specific version of Boost
287 # (eg, >= 1.33) you *must* invoke BOOST_REQUIRE before this macro.
288 AC_DEFUN([BOOST_FIND_LIB],
289 [AC_REQUIRE([BOOST_REQUIRE])dnl
290 AC_REQUIRE([_BOOST_FIND_COMPILER_TAG])dnl
291 AC_REQUIRE([BOOST_STATIC])dnl
292 AC_REQUIRE([_BOOST_GUESS_WHETHER_TO_USE_MT])dnl
293 if test x"$boost_cv_inc_path" = xno; then
294   AC_MSG_NOTICE([Boost not available, not searching for the Boost $1 library])
295 else
296 dnl The else branch is huge and wasn't intended on purpose.
297 AC_LANG_PUSH([C++])dnl
298 AS_VAR_PUSHDEF([Boost_lib], [boost_cv_lib_$1])dnl
299 AS_VAR_PUSHDEF([Boost_lib_LDFLAGS], [boost_cv_lib_$1_LDFLAGS])dnl
300 AS_VAR_PUSHDEF([Boost_lib_LDPATH], [boost_cv_lib_$1_LDPATH])dnl
301 AS_VAR_PUSHDEF([Boost_lib_LIBS], [boost_cv_lib_$1_LIBS])dnl
302 BOOST_FIND_HEADER([$3])
303 boost_save_CPPFLAGS=$CPPFLAGS
304 CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
305 # Now let's try to find the library.  The algorithm is as follows: first look
306 # for a given library name according to the user's PREFERRED-RT-OPT.  For each
307 # library name, we prefer to use the ones that carry the tag (toolset name).
308 # Each library is searched through the various standard paths were Boost is
309 # usually installed.  If we can't find the standard variants, we try to
310 # enforce -mt (for instance on MacOSX, libboost_threads.dylib doesn't exist
311 # but there's -obviously- libboost_threads-mt.dylib).
312 AC_CACHE_CHECK([for the Boost $1 library], [Boost_lib],
313   [Boost_lib=no
314   case "$2" in #(
315     mt | mt-) boost_mt=-mt; boost_rtopt=;; #(
316     mt* | mt-*) boost_mt=-mt; boost_rtopt=`expr "X$2" : 'Xmt-*\(.*\)'`;; #(
317     *) boost_mt=; boost_rtopt=$2;;
318   esac
319   if test $enable_static_boost = yes; then
320     boost_rtopt="s$boost_rtopt"
321   fi
322   # Find the proper debug variant depending on what we've been asked to find.
323   case $boost_rtopt in #(
324     *d*) boost_rt_d=$boost_rtopt;; #(
325     *[[sgpn]]*) # Insert the `d' at the right place (in between `sg' and `pn')
326       boost_rt_d=`echo "$boost_rtopt" | sed 's/\(s*g*\)\(p*n*\)/\1\2/'`;; #(
327     *) boost_rt_d='-d';;
328   esac
329   # If the PREFERRED-RT-OPT are not empty, prepend a `-'.
330   test -n "$boost_rtopt" && boost_rtopt="-$boost_rtopt"
331   $boost_guess_use_mt && boost_mt=-mt
332   # Look for the abs path the static archive.
333   # $libext is computed by Libtool but let's make sure it's non empty.
334   test -z "$libext" &&
335     AC_MSG_ERROR([the libext variable is empty, did you invoke Libtool?])
336   boost_save_ac_objext=$ac_objext
337   # Generate the test file.
338   AC_LANG_CONFTEST([AC_LANG_PROGRAM([#include <$3>
339 $5], [$4])])
340 dnl Optimization hacks: compiling C++ is slow, especially with Boost.  What
341 dnl we're trying to do here is guess the right combination of link flags
342 dnl (LIBS / LDFLAGS) to use a given library.  This can take several
343 dnl iterations before it succeeds and is thus *very* slow.  So what we do
344 dnl instead is that we compile the code first (and thus get an object file,
345 dnl typically conftest.o).  Then we try various combinations of link flags
346 dnl until we succeed to link conftest.o in an executable.  The problem is
347 dnl that the various TRY_LINK / COMPILE_IFELSE macros of Autoconf always
348 dnl remove all the temporary files including conftest.o.  So the trick here
349 dnl is to temporarily change the value of ac_objext so that conftest.o is
350 dnl preserved accross tests.  This is obviously fragile and I will burn in
351 dnl hell for not respecting Autoconf's documented interfaces, but in the
352 dnl mean time, it optimizes the macro by a factor of 5 to 30.
353 dnl Another small optimization: the first argument of AC_COMPILE_IFELSE left
354 dnl empty because the test file is generated only once above (before we
355 dnl start the for loops).
356   AC_COMPILE_IFELSE([],
357     [ac_objext=do_not_rm_me_plz],
358     [AC_MSG_ERROR([cannot compile a test that uses Boost $1])])
359   ac_objext=$boost_save_ac_objext
360   boost_failed_libs=
361 # Don't bother to ident the 6 nested for loops, only the 2 innermost ones
362 # matter.
363 for boost_tag_ in -$boost_cv_lib_tag ''; do
364 for boost_ver_ in -$boost_cv_lib_version ''; do
365 for boost_mt_ in $boost_mt -mt ''; do
366 for boost_rtopt_ in $boost_rtopt '' -d; do
367   for boost_lib in \
368     boost_$1$boost_tag_$boost_mt_$boost_rtopt_$boost_ver_ \
369     boost_$1$boost_tag_$boost_rtopt_$boost_ver_ \
370     boost_$1$boost_tag_$boost_mt_$boost_ver_ \
371     boost_$1$boost_tag_$boost_ver_
372   do
373     # Avoid testing twice the same lib
374     case $boost_failed_libs in #(
375       *@$boost_lib@*) continue;;
376     esac
377     # If with_boost is empty, we'll search in /lib first, which is not quite
378     # right so instead we'll try to a location based on where the headers are.
379     boost_tmp_lib=$with_boost
380     test x"$with_boost" = x && boost_tmp_lib=${boost_cv_inc_path%/include}
381     for boost_ldpath in "$boost_tmp_lib/lib" '' \
382              /opt/local/lib* /usr/local/lib* /opt/lib* /usr/lib* \
383              "$with_boost" C:/Boost/lib /lib*
384     do
385       test -e "$boost_ldpath" || continue
386       boost_save_LDFLAGS=$LDFLAGS
387       # Are we looking for a static library?
388       case $boost_ldpath:$boost_rtopt_ in #(
389         *?*:*s*) # Yes (Non empty boost_ldpath + s in rt opt)
390           Boost_lib_LIBS="$boost_ldpath/lib$boost_lib.$libext"
391           test -e "$Boost_lib_LIBS" || continue;; #(
392         *) # No: use -lboost_foo to find the shared library.
393           Boost_lib_LIBS="-l$boost_lib";;
394       esac
395       boost_save_LIBS=$LIBS
396       LIBS="$Boost_lib_LIBS $LIBS"
397       test x"$boost_ldpath" != x && LDFLAGS="$LDFLAGS -L$boost_ldpath"
398 dnl First argument of AC_LINK_IFELSE left empty because the test file is
399 dnl generated only once above (before we start the for loops).
400       _BOOST_AC_LINK_IFELSE([],
401                             [Boost_lib=yes], [Boost_lib=no])
402       ac_objext=$boost_save_ac_objext
403       LDFLAGS=$boost_save_LDFLAGS
404       LIBS=$boost_save_LIBS
405       if test x"$Boost_lib" = xyes; then
406         Boost_lib_LDFLAGS="-L$boost_ldpath -Wl,-R$boost_ldpath"
407         Boost_lib_LDPATH="$boost_ldpath"
408         break 6
409       else
410         boost_failed_libs="$boost_failed_libs@$boost_lib@"
411       fi
412     done
413   done
414 done
415 done
416 done
417 done
418 rm -f conftest.$ac_objext
419 ])
420 case $Boost_lib in #(
421   no) _AC_MSG_LOG_CONFTEST
422     AC_MSG_ERROR([cannot find the flags to link with Boost $1])
423     ;;
424 esac
425 AC_SUBST(AS_TR_CPP([BOOST_$1_LDFLAGS]), [$Boost_lib_LDFLAGS])dnl
426 AC_SUBST(AS_TR_CPP([BOOST_$1_LDPATH]), [$Boost_lib_LDPATH])dnl
427 AC_SUBST([BOOST_LDPATH], [$Boost_lib_LDPATH])dnl
428 AC_SUBST(AS_TR_CPP([BOOST_$1_LIBS]), [$Boost_lib_LIBS])dnl
429 CPPFLAGS=$boost_save_CPPFLAGS
430 AS_VAR_POPDEF([Boost_lib])dnl
431 AS_VAR_POPDEF([Boost_lib_LDFLAGS])dnl
432 AS_VAR_POPDEF([Boost_lib_LDPATH])dnl
433 AS_VAR_POPDEF([Boost_lib_LIBS])dnl
434 AC_LANG_POP([C++])dnl
435 fi
436 ])# BOOST_FIND_LIB
437
438
439 # --------------------------------------- #
440 # Checks for the various Boost libraries. #
441 # --------------------------------------- #
442
443 # List of boost libraries: http://www.boost.org/libs/libraries.htm
444 # The page http://beta.boost.org/doc/libs is useful: it gives the first release
445 # version of each library (among other things).
446
447 # BOOST_DEFUN(LIBRARY, CODE)
448 # --------------------------
449 # Define BOOST_<LIBRARY-UPPERCASE> as a macro that runs CODE.
450 #
451 # Use indir to avoid the warning on underquoted macro name given to AC_DEFUN.
452 m4_define([BOOST_DEFUN],
453 [m4_indir([AC_DEFUN],
454           m4_toupper([BOOST_$1]),
455 [m4_pushdef([BOOST_Library], [$1])dnl
456 $2
457 m4_popdef([BOOST_Library])dnl
458 ])
459 ])
460
461 # BOOST_ARRAY()
462 # -------------
463 # Look for Boost.Array
464 BOOST_DEFUN([Array],
465 [BOOST_FIND_HEADER([boost/array.hpp])])
466
467
468 # BOOST_ASIO()
469 # ------------
470 # Look for Boost.Asio (new in Boost 1.35).
471 BOOST_DEFUN([Asio],
472 [AC_REQUIRE([BOOST_SYSTEM])dnl
473 BOOST_FIND_HEADER([boost/asio.hpp])])
474
475
476 # BOOST_BIND()
477 # ------------
478 # Look for Boost.Bind
479 BOOST_DEFUN([Bind],
480 [BOOST_FIND_HEADER([boost/bind.hpp])])
481
482
483 # BOOST_CHRONO()
484 # ------------------
485 # Look for Boost.Chrono
486 BOOST_DEFUN([Chrono],
487 [# Do we have to check for Boost.System?  This link-time dependency was
488 # added as of 1.35.0.  If we have a version <1.35, we must not attempt to
489 # find Boost.System as it didn't exist by then.
490 if test $boost_major_version -ge 135; then
491 BOOST_SYSTEM([$1])
492 fi # end of the Boost.System check.
493 boost_filesystem_save_LIBS=$LIBS
494 boost_filesystem_save_LDFLAGS=$LDFLAGS
495 m4_pattern_allow([^BOOST_SYSTEM_(LIBS|LDFLAGS)$])dnl
496 LIBS="$LIBS $BOOST_SYSTEM_LIBS"
497 LDFLAGS="$LDFLAGS $BOOST_SYSTEM_LDFLAGS"
498 BOOST_FIND_LIB([chrono], [$1],
499                 [boost/chrono.hpp],
500                 [boost::chrono::thread_clock d;])
501 if test $enable_static_boost = yes && test $boost_major_version -ge 135; then
502     AC_SUBST([BOOST_FILESYSTEM_LIBS], ["$BOOST_FILESYSTEM_LIBS $BOOST_SYSTEM_LIBS"])
503 fi
504 LIBS=$boost_filesystem_save_LIBS
505 LDFLAGS=$boost_filesystem_save_LDFLAGS
506
507 ])# BOOST_CHRONO
508
509
510 # BOOST_CONVERSION()
511 # ------------------
512 # Look for Boost.Conversion (cast / lexical_cast)
513 BOOST_DEFUN([Conversion],
514 [BOOST_FIND_HEADER([boost/cast.hpp])
515 BOOST_FIND_HEADER([boost/lexical_cast.hpp])
516 ])# BOOST_CONVERSION
517
518
519 # BOOST_DATE_TIME([PREFERRED-RT-OPT])
520 # -----------------------------------
521 # Look for Boost.Date_Time.  For the documentation of PREFERRED-RT-OPT, see the
522 # documentation of BOOST_FIND_LIB above.
523 BOOST_DEFUN([Date_Time],
524 [BOOST_FIND_LIB([date_time], [$1],
525                 [boost/date_time/posix_time/posix_time.hpp],
526                 [boost::posix_time::ptime t;])
527 ])# BOOST_DATE_TIME
528
529
530 # BOOST_FILESYSTEM([PREFERRED-RT-OPT])
531 # ------------------------------------
532 # Look for Boost.Filesystem.  For the documentation of PREFERRED-RT-OPT, see
533 # the documentation of BOOST_FIND_LIB above.
534 # Do not check for boost/filesystem.hpp because this file was introduced in
535 # 1.34.
536 BOOST_DEFUN([Filesystem],
537 [# Do we have to check for Boost.System?  This link-time dependency was
538 # added as of 1.35.0.  If we have a version <1.35, we must not attempt to
539 # find Boost.System as it didn't exist by then.
540 if test $boost_major_version -ge 135; then
541 BOOST_SYSTEM([$1])
542 fi # end of the Boost.System check.
543 boost_filesystem_save_LIBS=$LIBS
544 boost_filesystem_save_LDFLAGS=$LDFLAGS
545 m4_pattern_allow([^BOOST_SYSTEM_(LIBS|LDFLAGS)$])dnl
546 LIBS="$LIBS $BOOST_SYSTEM_LIBS"
547 LDFLAGS="$LDFLAGS $BOOST_SYSTEM_LDFLAGS"
548 BOOST_FIND_LIB([filesystem], [$1],
549                 [boost/filesystem/path.hpp], [boost::filesystem::path p;])
550 if test $enable_static_boost = yes && test $boost_major_version -ge 135; then
551     AC_SUBST([BOOST_FILESYSTEM_LIBS], ["$BOOST_FILESYSTEM_LIBS $BOOST_SYSTEM_LIBS"])
552 fi
553 LIBS=$boost_filesystem_save_LIBS
554 LDFLAGS=$boost_filesystem_save_LDFLAGS
555 ])# BOOST_FILESYSTEM
556
557
558 # BOOST_FOREACH()
559 # ---------------
560 # Look for Boost.Foreach
561 BOOST_DEFUN([Foreach],
562 [BOOST_FIND_HEADER([boost/foreach.hpp])])
563
564
565 # BOOST_FORMAT()
566 # --------------
567 # Look for Boost.Format
568 # Note: we can't check for boost/format/format_fwd.hpp because the header isn't
569 # standalone.  It can't be compiled because it triggers the following error:
570 # boost/format/detail/config_macros.hpp:88: error: 'locale' in namespace 'std'
571 #                                                  does not name a type
572 BOOST_DEFUN([Format],
573 [BOOST_FIND_HEADER([boost/format.hpp])])
574
575
576 # BOOST_FUNCTION()
577 # ----------------
578 # Look for Boost.Function
579 BOOST_DEFUN([Function],
580 [BOOST_FIND_HEADER([boost/function.hpp])])
581
582
583 # BOOST_GRAPH([PREFERRED-RT-OPT])
584 # -------------------------------
585 # Look for Boost.Graphs.  For the documentation of PREFERRED-RT-OPT, see the
586 # documentation of BOOST_FIND_LIB above.
587 BOOST_DEFUN([Graph],
588 [BOOST_FIND_LIB([graph], [$1],
589                 [boost/graph/adjacency_list.hpp], [boost::adjacency_list<> g;])
590 ])# BOOST_GRAPH
591
592
593 # BOOST_IOSTREAMS([PREFERRED-RT-OPT])
594 # -----------------------------------
595 # Look for Boost.IOStreams.  For the documentation of PREFERRED-RT-OPT, see the
596 # documentation of BOOST_FIND_LIB above.
597 BOOST_DEFUN([IOStreams],
598 [BOOST_FIND_LIB([iostreams], [$1],
599                 [boost/iostreams/device/file_descriptor.hpp],
600                 [boost::iostreams::file_descriptor fd; fd.close();])
601 ])# BOOST_IOSTREAMS
602
603
604 # BOOST_HASH()
605 # ------------
606 # Look for Boost.Functional/Hash
607 BOOST_DEFUN([Hash],
608 [BOOST_FIND_HEADER([boost/functional/hash.hpp])])
609
610
611 # BOOST_LAMBDA()
612 # --------------
613 # Look for Boost.Lambda
614 BOOST_DEFUN([Lambda],
615 [BOOST_FIND_HEADER([boost/lambda/lambda.hpp])])
616
617
618 # BOOST_LOG([PREFERRED-RT-OPT])
619 # -----------------------------
620 # Look for Boost.Log For the documentation of PREFERRED-RT-OPT, see the
621 # documentation of BOOST_FIND_LIB above.
622 BOOST_DEFUN([Log],
623 [BOOST_FIND_LIB([log], [$1],
624     [boost/log/core/core.hpp],
625     [boost::log::attribute a; a.get_value();])
626 ])# BOOST_LOG
627
628
629 # BOOST_LOG_SETUP([PREFERRED-RT-OPT])
630 # -----------------------------------
631 # Look for Boost.Log For the documentation of PREFERRED-RT-OPT, see the
632 # documentation of BOOST_FIND_LIB above.
633 BOOST_DEFUN([Log_Setup],
634 [AC_REQUIRE([BOOST_LOG])dnl
635 BOOST_FIND_LIB([log_setup], [$1],
636     [boost/log/utility/init/from_settings.hpp],
637     [boost::log::basic_settings<char> bs; bs.empty();])
638 ])# BOOST_LOG_SETUP
639
640
641 # BOOST_MATH()
642 # ------------
643 # Look for Boost.Math
644 # TODO: This library isn't header-only but it comes in multiple different
645 # flavors that don't play well with BOOST_FIND_LIB (e.g, libboost_math_c99,
646 # libboost_math_c99f, libboost_math_c99l, libboost_math_tr1,
647 # libboost_math_tr1f, libboost_math_tr1l).  This macro must be fixed to do the
648 # right thing anyway.
649 BOOST_DEFUN([Math],
650 [BOOST_FIND_HEADER([boost/math/special_functions.hpp])])
651
652
653 # BOOST_MULTIARRAY()
654 # ------------------
655 # Look for Boost.MultiArray
656 BOOST_DEFUN([MultiArray],
657 [BOOST_FIND_HEADER([boost/multi_array.hpp])])
658
659
660 # BOOST_NUMERIC_CONVERSION()
661 # --------------------------
662 # Look for Boost.NumericConversion (policy-based numeric conversion)
663 BOOST_DEFUN([Numeric_Conversion],
664 [BOOST_FIND_HEADER([boost/numeric/conversion/converter.hpp])
665 ])# BOOST_NUMERIC_CONVERSION
666
667
668 # BOOST_OPTIONAL()
669 # ----------------
670 # Look for Boost.Optional
671 BOOST_DEFUN([Optional],
672 [BOOST_FIND_HEADER([boost/optional.hpp])])
673
674
675 # BOOST_PREPROCESSOR()
676 # --------------------
677 # Look for Boost.Preprocessor
678 BOOST_DEFUN([Preprocessor],
679 [BOOST_FIND_HEADER([boost/preprocessor/repeat.hpp])])
680
681
682 # BOOST_UNORDERED()
683 # -----------------
684 # Look for Boost.Unordered
685 BOOST_DEFUN([Unordered],
686 [BOOST_FIND_HEADER([boost/unordered_map.hpp])])
687
688
689 # BOOST_UUID()
690 # ------------
691 # Look for Boost.Uuid
692 BOOST_DEFUN([Uuid],
693 [BOOST_FIND_HEADER([boost/uuid/uuid.hpp])])
694
695
696 # BOOST_PROGRAM_OPTIONS([PREFERRED-RT-OPT])
697 # -----------------------------------------
698 # Look for Boost.Program_options.  For the documentation of PREFERRED-RT-OPT,
699 # see the documentation of BOOST_FIND_LIB above.
700 BOOST_DEFUN([Program_Options],
701 [BOOST_FIND_LIB([program_options], [$1],
702                 [boost/program_options.hpp],
703                 [boost::program_options::options_description d("test");])
704 ])# BOOST_PROGRAM_OPTIONS
705
706
707
708 # _BOOST_PYTHON_CONFIG(VARIABLE, FLAG)
709 # ------------------------------------
710 # Save VARIABLE, and define it via `python-config --FLAG`.
711 # Substitute BOOST_PYTHON_VARIABLE.
712 m4_define([_BOOST_PYTHON_CONFIG],
713 [AC_SUBST([BOOST_PYTHON_$1],
714           [`python-config --$2 2>/dev/null`])dnl
715 boost_python_save_$1=$$1
716 $1="$$1 $BOOST_PYTHON_$1"])
717
718
719 # BOOST_PYTHON([PREFERRED-RT-OPT])
720 # --------------------------------
721 # Look for Boost.Python.  For the documentation of PREFERRED-RT-OPT,
722 # see the documentation of BOOST_FIND_LIB above.
723 BOOST_DEFUN([Python],
724 [_BOOST_PYTHON_CONFIG([CPPFLAGS], [includes])
725 _BOOST_PYTHON_CONFIG([LDFLAGS],   [ldflags])
726 _BOOST_PYTHON_CONFIG([LIBS],      [libs])
727 m4_pattern_allow([^BOOST_PYTHON_MODULE$])dnl
728 BOOST_FIND_LIB([python], [$1],
729                [boost/python.hpp],
730                [], [BOOST_PYTHON_MODULE(empty) {}])
731 CPPFLAGS=$boost_python_save_CPPFLAGS
732 LDFLAGS=$boost_python_save_LDFLAGS
733 LIBS=$boost_python_save_LIBS
734 ])# BOOST_PYTHON
735
736
737 # BOOST_REF()
738 # -----------
739 # Look for Boost.Ref
740 BOOST_DEFUN([Ref],
741 [BOOST_FIND_HEADER([boost/ref.hpp])])
742
743
744 # BOOST_REGEX([PREFERRED-RT-OPT])
745 # -------------------------------
746 # Look for Boost.Regex.  For the documentation of PREFERRED-RT-OPT, see the
747 # documentation of BOOST_FIND_LIB above.
748 BOOST_DEFUN([Regex],
749 [BOOST_FIND_LIB([regex], [$1],
750                 [boost/regex.hpp],
751                 [boost::regex exp("*"); boost::regex_match("foo", exp);])
752 ])# BOOST_REGEX
753
754
755 # BOOST_SERIALIZATION([PREFERRED-RT-OPT])
756 # ---------------------------------------
757 # Look for Boost.Serialization.  For the documentation of PREFERRED-RT-OPT, see
758 # the documentation of BOOST_FIND_LIB above.
759 BOOST_DEFUN([Serialization],
760 [BOOST_FIND_LIB([serialization], [$1],
761                 [boost/archive/text_oarchive.hpp],
762                 [std::ostream* o = 0; // Cheap way to get an ostream...
763                 boost::archive::text_oarchive t(*o);])
764 ])# BOOST_SERIALIZATION
765
766
767 # BOOST_SIGNALS([PREFERRED-RT-OPT])
768 # ---------------------------------
769 # Look for Boost.Signals.  For the documentation of PREFERRED-RT-OPT, see the
770 # documentation of BOOST_FIND_LIB above.
771 BOOST_DEFUN([Signals],
772 [BOOST_FIND_LIB([signals], [$1],
773                 [boost/signal.hpp],
774                 [boost::signal<void ()> s;])
775 ])# BOOST_SIGNALS
776
777
778 # BOOST_SMART_PTR()
779 # -----------------
780 # Look for Boost.SmartPtr
781 BOOST_DEFUN([Smart_Ptr],
782 [BOOST_FIND_HEADER([boost/scoped_ptr.hpp])
783 BOOST_FIND_HEADER([boost/shared_ptr.hpp])
784 ])
785
786
787 # BOOST_STATICASSERT()
788 # --------------------
789 # Look for Boost.StaticAssert
790 BOOST_DEFUN([StaticAssert],
791 [BOOST_FIND_HEADER([boost/static_assert.hpp])])
792
793
794 # BOOST_STRING_ALGO()
795 # -------------------
796 # Look for Boost.StringAlgo
797 BOOST_DEFUN([String_Algo],
798 [BOOST_FIND_HEADER([boost/algorithm/string.hpp])
799 ])
800
801
802 # BOOST_SYSTEM([PREFERRED-RT-OPT])
803 # --------------------------------
804 # Look for Boost.System.  For the documentation of PREFERRED-RT-OPT, see the
805 # documentation of BOOST_FIND_LIB above.  This library was introduced in Boost
806 # 1.35.0.
807 BOOST_DEFUN([System],
808 [BOOST_FIND_LIB([system], [$1],
809                 [boost/system/error_code.hpp],
810                 [boost::system::error_code e; e.clear();])
811 ])# BOOST_SYSTEM
812
813
814 # BOOST_TEST([PREFERRED-RT-OPT])
815 # ------------------------------
816 # Look for Boost.Test.  For the documentation of PREFERRED-RT-OPT, see the
817 # documentation of BOOST_FIND_LIB above.
818 BOOST_DEFUN([Test],
819 [m4_pattern_allow([^BOOST_CHECK$])dnl
820 BOOST_FIND_LIB([unit_test_framework], [$1],
821                [boost/test/unit_test.hpp], [BOOST_CHECK(2 == 2);],
822                [using boost::unit_test::test_suite;
823                test_suite* init_unit_test_suite(int argc, char ** argv)
824                { return NULL; }])
825 ])# BOOST_TEST
826
827
828 # BOOST_THREADS([PREFERRED-RT-OPT])
829 # ---------------------------------
830 # Look for Boost.Thread.  For the documentation of PREFERRED-RT-OPT, see the
831 # documentation of BOOST_FIND_LIB above.
832 # FIXME: Provide an alias "BOOST_THREAD".
833 BOOST_DEFUN([Threads],
834 [dnl Having the pthread flag is required at least on GCC3 where
835 dnl boost/thread.hpp would complain if we try to compile without
836 dnl -pthread on GNU/Linux.
837 AC_REQUIRE([_BOOST_PTHREAD_FLAG])dnl
838 boost_threads_save_LIBS=$LIBS
839 boost_threads_save_LDFLAGS=$LDFLAGS
840 boost_threads_save_CPPFLAGS=$CPPFLAGS
841 # Link-time dependency from thread to system was added as of 1.49.0.
842 if test $boost_major_version -ge 149; then
843 BOOST_SYSTEM([$1])
844 fi # end of the Boost.System check.
845 m4_pattern_allow([^BOOST_SYSTEM_(LIBS|LDFLAGS)$])dnl
846 LIBS="$LIBS $BOOST_SYSTEM_LIBS $boost_cv_pthread_flag"
847 LDFLAGS="$LDFLAGS $BOOST_SYSTEM_LDFLAGS"
848 # Yes, we *need* to put the -pthread thing in CPPFLAGS because with GCC3,
849 # boost/thread.hpp will trigger a #error if -pthread isn't used:
850 #   boost/config/requires_threads.hpp:47:5: #error "Compiler threading support
851 #   is not turned on. Please set the correct command line options for
852 #   threading: -pthread (Linux), -pthreads (Solaris) or -mthreads (Mingw32)"
853 CPPFLAGS="$CPPFLAGS $boost_cv_pthread_flag"
854
855 # When compiling for the Windows platform, the threads library is named
856 # differently.
857 case $host_os in
858   (*mingw*)
859     BOOST_FIND_LIB([thread_win32], [$1],
860                    [boost/thread.hpp], [boost::thread t; boost::mutex m;])
861     BOOST_THREAD_LDFLAGS=$BOOST_THREAD_WIN32_LDFLAGS
862     BOOST_THREAD_LDPATH=$BOOST_THREAD_WIN32_LDPATH
863     BOOST_THREAD_LIBS=$BOOST_THREAD_WIN32_LIBS
864   ;;
865   (*)
866     BOOST_FIND_LIB([thread], [$1],
867                    [boost/thread.hpp], [boost::thread t; boost::mutex m;])
868   ;;
869 esac
870
871 BOOST_THREAD_LIBS="$BOOST_THREAD_LIBS $BOOST_SYSTEM_LIBS $boost_cv_pthread_flag"
872 BOOST_THREAD_LDFLAGS="$BOOST_SYSTEM_LDFLAGS"
873 BOOST_CPPFLAGS="$BOOST_CPPFLAGS $boost_cv_pthread_flag"
874 LIBS=$boost_threads_save_LIBS
875 LDFLAGS=$boost_threads_save_LDFLAGS
876 CPPFLAGS=$boost_threads_save_CPPFLAGS
877 ])# BOOST_THREADS
878
879
880 # BOOST_TOKENIZER()
881 # -----------------
882 # Look for Boost.Tokenizer
883 BOOST_DEFUN([Tokenizer],
884 [BOOST_FIND_HEADER([boost/tokenizer.hpp])])
885
886
887 # BOOST_TRIBOOL()
888 # ---------------
889 # Look for Boost.Tribool
890 BOOST_DEFUN([Tribool],
891 [BOOST_FIND_HEADER([boost/logic/tribool_fwd.hpp])
892 BOOST_FIND_HEADER([boost/logic/tribool.hpp])
893 ])
894
895
896 # BOOST_TUPLE()
897 # -------------
898 # Look for Boost.Tuple
899 BOOST_DEFUN([Tuple],
900 [BOOST_FIND_HEADER([boost/tuple/tuple.hpp])])
901
902
903 # BOOST_TYPETRAITS()
904 # --------------------
905 # Look for Boost.TypeTraits
906 BOOST_DEFUN([TypeTraits],
907 [BOOST_FIND_HEADER([boost/type_traits.hpp])])
908
909
910 # BOOST_UTILITY()
911 # ---------------
912 # Look for Boost.Utility (noncopyable, result_of, base-from-member idiom,
913 # etc.)
914 BOOST_DEFUN([Utility],
915 [BOOST_FIND_HEADER([boost/utility.hpp])])
916
917
918 # BOOST_VARIANT()
919 # ---------------
920 # Look for Boost.Variant.
921 BOOST_DEFUN([Variant],
922 [BOOST_FIND_HEADER([boost/variant/variant_fwd.hpp])
923 BOOST_FIND_HEADER([boost/variant.hpp])])
924
925
926 # BOOST_WAVE([PREFERRED-RT-OPT])
927 # ------------------------------
928 # NOTE: If you intend to use Wave/Spirit with thread support, make sure you
929 # call BOOST_THREADS first.
930 # Look for Boost.Wave.  For the documentation of PREFERRED-RT-OPT, see the
931 # documentation of BOOST_FIND_LIB above.
932 BOOST_DEFUN([Wave],
933 [AC_REQUIRE([BOOST_FILESYSTEM])dnl
934 AC_REQUIRE([BOOST_DATE_TIME])dnl
935 boost_wave_save_LIBS=$LIBS
936 boost_wave_save_LDFLAGS=$LDFLAGS
937 m4_pattern_allow([^BOOST_((FILE)?SYSTEM|DATE_TIME|THREAD)_(LIBS|LDFLAGS)$])dnl
938 LIBS="$LIBS $BOOST_SYSTEM_LIBS $BOOST_FILESYSTEM_LIBS $BOOST_DATE_TIME_LIBS \
939 $BOOST_THREAD_LIBS"
940 LDFLAGS="$LDFLAGS $BOOST_SYSTEM_LDFLAGS $BOOST_FILESYSTEM_LDFLAGS \
941 $BOOST_DATE_TIME_LDFLAGS $BOOST_THREAD_LDFLAGS"
942 BOOST_FIND_LIB([wave], [$1],
943                 [boost/wave.hpp],
944                 [boost::wave::token_id id; get_token_name(id);])
945 LIBS=$boost_wave_save_LIBS
946 LDFLAGS=$boost_wave_save_LDFLAGS
947 ])# BOOST_WAVE
948
949
950 # BOOST_XPRESSIVE()
951 # -----------------
952 # Look for Boost.Xpressive (new since 1.36.0).
953 BOOST_DEFUN([Xpressive],
954 [BOOST_FIND_HEADER([boost/xpressive/xpressive.hpp])])
955
956
957 # ----------------- #
958 # Internal helpers. #
959 # ----------------- #
960
961
962 # _BOOST_PTHREAD_FLAG()
963 # ---------------------
964 # Internal helper for BOOST_THREADS.  Based on ACX_PTHREAD:
965 # http://autoconf-archive.cryp.to/acx_pthread.html
966 AC_DEFUN([_BOOST_PTHREAD_FLAG],
967 [AC_REQUIRE([AC_PROG_CXX])dnl
968 AC_REQUIRE([AC_CANONICAL_HOST])dnl
969 AC_LANG_PUSH([C++])dnl
970 AC_CACHE_CHECK([for the flags needed to use pthreads], [boost_cv_pthread_flag],
971 [ boost_cv_pthread_flag=
972   # The ordering *is* (sometimes) important.  Some notes on the
973   # individual items follow:
974   # (none): in case threads are in libc; should be tried before -Kthread and
975   #       other compiler flags to prevent continual compiler warnings
976   # -lpthreads: AIX (must check this before -lpthread)
977   # -Kthread: Sequent (threads in libc, but -Kthread needed for pthread.h)
978   # -kthread: FreeBSD kernel threads (preferred to -pthread since SMP-able)
979   # -llthread: LinuxThreads port on FreeBSD (also preferred to -pthread)
980   # -pthread: GNU Linux/GCC (kernel threads), BSD/GCC (userland threads)
981   # -pthreads: Solaris/GCC
982   # -mthreads: MinGW32/GCC, Lynx/GCC
983   # -mt: Sun Workshop C (may only link SunOS threads [-lthread], but it
984   #      doesn't hurt to check since this sometimes defines pthreads too;
985   #      also defines -D_REENTRANT)
986   #      ... -mt is also the pthreads flag for HP/aCC
987   # -lpthread: GNU Linux, etc.
988   # --thread-safe: KAI C++
989   case $host_os in #(
990     *solaris*)
991       # On Solaris (at least, for some versions), libc contains stubbed
992       # (non-functional) versions of the pthreads routines, so link-based
993       # tests will erroneously succeed.  (We need to link with -pthreads/-mt/
994       # -lpthread.)  (The stubs are missing pthread_cleanup_push, or rather
995       # a function called by this macro, so we could check for that, but
996       # who knows whether they'll stub that too in a future libc.)  So,
997       # we'll just look for -pthreads and -lpthread first:
998       boost_pthread_flags="-pthreads -lpthread -mt -pthread";; #(
999     *)
1000       boost_pthread_flags="-lpthreads -Kthread -kthread -llthread -pthread \
1001                            -pthreads -mthreads -lpthread --thread-safe -mt";;
1002   esac
1003   # Generate the test file.
1004   AC_LANG_CONFTEST([AC_LANG_PROGRAM([#include <pthread.h>],
1005     [pthread_t th; pthread_join(th, 0);
1006     pthread_attr_init(0); pthread_cleanup_push(0, 0);
1007     pthread_create(0,0,0,0); pthread_cleanup_pop(0);])])
1008   for boost_pthread_flag in '' $boost_pthread_flags; do
1009     boost_pthread_ok=false
1010 dnl Re-use the test file already generated.
1011     boost_pthreads__save_LIBS=$LIBS
1012     LIBS="$LIBS $boost_pthread_flag"
1013     AC_LINK_IFELSE([],
1014       [if grep ".*$boost_pthread_flag" conftest.err; then
1015          echo "This flag seems to have triggered warnings" >&AS_MESSAGE_LOG_FD
1016        else
1017          boost_pthread_ok=:; boost_cv_pthread_flag=$boost_pthread_flag
1018        fi])
1019     LIBS=$boost_pthreads__save_LIBS
1020     $boost_pthread_ok && break
1021   done
1022 ])
1023 AC_LANG_POP([C++])dnl
1024 ])# _BOOST_PTHREAD_FLAG
1025
1026
1027 # _BOOST_gcc_test(MAJOR, MINOR)
1028 # -----------------------------
1029 # Internal helper for _BOOST_FIND_COMPILER_TAG.
1030 m4_define([_BOOST_gcc_test],
1031 ["defined __GNUC__ && __GNUC__ == $1 && __GNUC_MINOR__ == $2 && !defined __ICC @ gcc$1$2"])dnl
1032
1033
1034 # _BOOST_FIND_COMPILER_TAG()
1035 # --------------------------
1036 # Internal.  When Boost is installed without --layout=system, each library
1037 # filename will hold a suffix that encodes the compiler used during the
1038 # build.  The Boost build system seems to call this a `tag'.
1039 AC_DEFUN([_BOOST_FIND_COMPILER_TAG],
1040 [AC_REQUIRE([AC_PROG_CXX])dnl
1041 AC_REQUIRE([AC_CANONICAL_HOST])dnl
1042 AC_CACHE_CHECK([for the toolset name used by Boost for $CXX], [boost_cv_lib_tag],
1043 [boost_cv_lib_tag=unknown
1044 if test x$boost_cv_inc_path != xno; then
1045   AC_LANG_PUSH([C++])dnl
1046   # The following tests are mostly inspired by boost/config/auto_link.hpp
1047   # The list is sorted to most recent/common to oldest compiler (in order
1048   # to increase the likelihood of finding the right compiler with the
1049   # least number of compilation attempt).
1050   # Beware that some tests are sensible to the order (for instance, we must
1051   # look for MinGW before looking for GCC3).
1052   # I used one compilation test per compiler with a #error to recognize
1053   # each compiler so that it works even when cross-compiling (let me know
1054   # if you know a better approach).
1055   # Known missing tags (known from Boost's tools/build/v2/tools/common.jam):
1056   #   como, edg, kcc, bck, mp, sw, tru, xlc
1057   # I'm not sure about my test for `il' (be careful: Intel's ICC pre-defines
1058   # the same defines as GCC's).
1059   for i in \
1060     _BOOST_gcc_test(4, 8) \
1061     _BOOST_gcc_test(4, 7) \
1062     _BOOST_gcc_test(4, 6) \
1063     _BOOST_gcc_test(4, 5) \
1064     _BOOST_gcc_test(4, 4) \
1065     _BOOST_gcc_test(4, 3) \
1066     _BOOST_gcc_test(4, 2) \
1067     _BOOST_gcc_test(4, 1) \
1068     _BOOST_gcc_test(4, 0) \
1069     "defined __GNUC__ && __GNUC__ == 3 && !defined __ICC \
1070      && (defined WIN32 || defined WINNT || defined _WIN32 || defined __WIN32 \
1071          || defined __WIN32__ || defined __WINNT || defined __WINNT__) @ mgw" \
1072     _BOOST_gcc_test(3, 4) \
1073     _BOOST_gcc_test(3, 3) \
1074     "defined _MSC_VER && _MSC_VER >= 1500 @ vc90" \
1075     "defined _MSC_VER && _MSC_VER == 1400 @ vc80" \
1076     _BOOST_gcc_test(3, 2) \
1077     "defined _MSC_VER && _MSC_VER == 1310 @ vc71" \
1078     _BOOST_gcc_test(3, 1) \
1079     _BOOST_gcc_test(3, 0) \
1080     "defined __BORLANDC__ @ bcb" \
1081     "defined __ICC && (defined __unix || defined __unix__) @ il" \
1082     "defined __ICL @ iw" \
1083     "defined _MSC_VER && _MSC_VER == 1300 @ vc7" \
1084     _BOOST_gcc_test(2, 95) \
1085     "defined __MWERKS__ && __MWERKS__ <= 0x32FF @ cw9" \
1086     "defined _MSC_VER && _MSC_VER < 1300 && !defined UNDER_CE @ vc6" \
1087     "defined _MSC_VER && _MSC_VER < 1300 && defined UNDER_CE @ evc4" \
1088     "defined __MWERKS__ && __MWERKS__ <= 0x31FF @ cw8"
1089   do
1090     boost_tag_test=`expr "X$i" : 'X\([[^@]]*\) @ '`
1091     boost_tag=`expr "X$i" : 'X[[^@]]* @ \(.*\)'`
1092     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1093 #if $boost_tag_test
1094 /* OK */
1095 #else
1096 # error $boost_tag_test
1097 #endif
1098 ]])], [boost_cv_lib_tag=$boost_tag; break], [])
1099   done
1100 AC_LANG_POP([C++])dnl
1101   case $boost_cv_lib_tag in #(
1102     # Some newer (>= 1.35?) versions of Boost seem to only use "gcc" as opposed
1103     # to "gcc41" for instance.
1104     *-gcc | *'-gcc ') :;; #(  Don't re-add -gcc: it's already in there.
1105     gcc*)
1106       boost_tag_x=
1107       case $host_os in #(
1108         darwin*)
1109           if test $boost_major_version -ge 136; then
1110             # The `x' added in r46793 of Boost.
1111             boost_tag_x=x
1112           fi;;
1113       esac
1114       # We can specify multiple tags in this variable because it's used by
1115       # BOOST_FIND_LIB that does a `for tag in -$boost_cv_lib_tag' ...
1116       boost_cv_lib_tag="$boost_tag_x$boost_cv_lib_tag -${boost_tag_x}gcc"
1117       ;; #(
1118     unknown)
1119       AC_MSG_WARN([[could not figure out which toolset name to use for $CXX]])
1120       boost_cv_lib_tag=
1121       ;;
1122   esac
1123 fi])dnl end of AC_CACHE_CHECK
1124 ])# _BOOST_FIND_COMPILER_TAG
1125
1126
1127 # _BOOST_GUESS_WHETHER_TO_USE_MT()
1128 # --------------------------------
1129 # Compile a small test to try to guess whether we should favor MT (Multi
1130 # Thread) flavors of Boost.  Sets boost_guess_use_mt accordingly.
1131 AC_DEFUN([_BOOST_GUESS_WHETHER_TO_USE_MT],
1132 [# Check whether we do better use `mt' even though we weren't ask to.
1133 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1134 #if defined _REENTRANT || defined _MT || defined __MT__
1135 /* use -mt */
1136 #else
1137 # error MT not needed
1138 #endif
1139 ]])], [boost_guess_use_mt=:], [boost_guess_use_mt=false])
1140 ])
1141
1142 # _BOOST_AC_LINK_IFELSE(PROGRAM, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
1143 # -------------------------------------------------------------------
1144 # Fork of _AC_LINK_IFELSE that preserves conftest.o across calls.  Fragile,
1145 # will break when Autoconf changes its internals.  Requires that you manually
1146 # rm -f conftest.$ac_objext in between to really different tests, otherwise
1147 # you will try to link a conftest.o left behind by a previous test.
1148 # Used to aggressively optimize BOOST_FIND_LIB (see the big comment in this
1149 # macro).
1150 #
1151 # Don't use "break" in the actions, as it would short-circuit some code
1152 # this macro runs after the actions.
1153 m4_define([_BOOST_AC_LINK_IFELSE],
1154 [m4_ifvaln([$1], [AC_LANG_CONFTEST([$1])])dnl
1155 rm -f conftest$ac_exeext
1156 boost_save_ac_ext=$ac_ext
1157 boost_use_source=:
1158 # If we already have a .o, re-use it.  We change $ac_ext so that $ac_link
1159 # tries to link the existing object file instead of compiling from source.
1160 test -f conftest.$ac_objext && ac_ext=$ac_objext && boost_use_source=false &&
1161   _AS_ECHO_LOG([re-using the existing conftest.$ac_objext])
1162 AS_IF([_AC_DO_STDERR($ac_link) && {
1163          test -z "$ac_[]_AC_LANG_ABBREV[]_werror_flag" ||
1164          test ! -s conftest.err
1165        } && test -s conftest$ac_exeext && {
1166          test "$cross_compiling" = yes ||
1167          $as_executable_p conftest$ac_exeext
1168 dnl FIXME: use AS_TEST_X instead when 2.61 is widespread enough.
1169        }],
1170       [$2],
1171       [if $boost_use_source; then
1172          _AC_MSG_LOG_CONFTEST
1173        fi
1174        $3])
1175 ac_objext=$boost_save_ac_objext
1176 ac_ext=$boost_save_ac_ext
1177 dnl Delete also the IPA/IPO (Inter Procedural Analysis/Optimization)
1178 dnl information created by the PGI compiler (conftest_ipa8_conftest.oo),
1179 dnl as it would interfere with the next link command.
1180 rm -f core conftest.err conftest_ipa8_conftest.oo \
1181       conftest$ac_exeext m4_ifval([$1], [conftest.$ac_ext])[]dnl
1182 ])# _BOOST_AC_LINK_IFELSE
1183
1184 # Local Variables:
1185 # mode: autoconf
1186 # End: