More windows fixes
[dyninst.git] / CMakeLists.txt
1 cmake_minimum_required (VERSION 2.6.4)
2 project (Dyninst)
3
4 set (DYNINST_ROOT ${PROJECT_SOURCE_DIR})
5
6 include (${DYNINST_ROOT}/cmake/shared.cmake)
7
8 if(${PLATFORM} MATCHES nt)
9   set (HEADER_DIRS common
10     dataflowAPI
11     dyninstAPI
12     dynutil
13     instructionAPI
14     parseAPI
15     patchAPI
16     proccontrol
17     stackwalk
18     symtabAPI
19     )
20 else()
21   set (HEADER_DIRS common
22     dataflowAPI
23     dwarf
24     dyninstAPI
25     dynutil
26     elf
27     instructionAPI
28     parseAPI
29     patchAPI
30     proccontrol
31     stackwalk
32     symlite
33     symtabAPI
34     )
35 endif()
36
37 foreach (dir ${HEADER_DIRS})
38   include_directories ( ${DYNINST_ROOT}/${dir}/h )
39 endforeach()
40
41 include_directories (
42   ${DYNINST_ROOT}
43   ${DYNINST_ROOT}/external
44   )
45
46 # Component time
47 add_subdirectory (common)
48 if(NOT ${PLATFORM} MATCHES nt)
49   add_subdirectory (elf)
50   add_subdirectory (dwarf)
51   add_subdirectory (symlite)
52 endif()
53 add_subdirectory (instructionAPI)
54 add_subdirectory (symtabAPI)
55 add_subdirectory (parseAPI)
56 add_subdirectory (patchAPI)
57 add_subdirectory (proccontrol)
58 add_subdirectory (stackwalk)
59 add_subdirectory (dyninstAPI)
60
61 #Build the RT library as a seperate project so we can change compilers
62 set(RT_SOURCE_DIR ${DYNINST_ROOT}/dyninstAPI_RT)
63 set(RT_BINARY_DIR ${PROJECT_BINARY_DIR}/dyninstAPI_RT)
64 file(MAKE_DIRECTORY ${RT_BINARY_DIR})
65 if (PLATFORM MATCHES bgq)
66   set (RT_C_COMPILER mpicc)
67 else()
68   set (RT_C_COMPILER ${CMAKE_C_COMPILER})
69 endif()
70
71 message(STATUS "Configuring RT library")
72
73 execute_process(WORKING_DIRECTORY ${RT_BINARY_DIR}
74   COMMAND ${CMAKE_COMMAND}
75   -DCMAKE_C_COMPILER=${RT_C_COMPILER}
76   -DCMAKE_BUILD_TYPE=${CMAKE_BUILD_TYPE}
77   -DCMAKE_INSTALL_PREFIX=${CMAKE_INSTALL_PREFIX}
78   -DCMAKE_C_FLAGS=${CMAKE_C_FLAGS}
79   -DPLATFORM=${PLATFORM}
80   -G ${CMAKE_GENERATOR}
81   ${RT_SOURCE_DIR})
82
83
84 add_custom_target(DyninstRT
85   ALL
86   #  COMMAND ${CMAKE_COMMAND} -E chdir ${RT_BINARY_DIR} ${ACTUAL_BUILD}
87   ${CMAKE_BUILD_TOOL}
88   WORKING_DIRECTORY ${RT_BINARY_DIR}
89   COMMENT "Building DyninstRT")
90
91
92
93 if(UNIX)
94   message(STATUS "Adding Unix-specific dependencies")
95   add_dependencies(dynDwarf libdwarf_imp)
96   add_dependencies(dynElf libelf_imp)
97   message(STATUS "Added libdwarf_imp and libelf_imp dependencies")
98   if (NOT USE_GNU_DEMANGLER)
99     add_dependencies(common libiberty_imp)
100   endif()
101   if(NOT LIBDWARF_FOUND)
102     message(STATUS "Building libdwarf, creating libdwarf dependency on libelf")
103     add_dependencies(libdwarf_imp libelf_imp)
104   endif()
105 endif()
106
107 if(NOT ${PLATFORM} MATCHES nt)
108   SET_TARGET_PROPERTIES (
109     common dynElf dynDwarf instructionAPI symtabAPI symLite parseAPI
110     patchAPI pcontrol stackwalk dyninstAPI
111     PROPERTIES
112     SOVERSION ${SOVERSION}
113     VERSION ${LIBVERSION}
114     CLEAN_DIRECT_OUTPUT 1
115     )
116 else()
117   SET_TARGET_PROPERTIES (
118     common instructionAPI symtabAPI parseAPI
119     patchAPI pcontrol stackwalk dyninstAPI
120     PROPERTIES
121     SOVERSION ${SOVERSION}
122     VERSION ${LIBVERSION}
123     CLEAN_DIRECT_OUTPUT 1
124
125     )
126
127 endif()
128
129 if(UNIX)
130   if(SHOULD_INSTALL_LIBELF)
131     get_filename_component(ELFDIR "${LIBELF_LIBRARIES}" PATH)
132     file(GLOB LIBELF_INSTALL_FILES ${ELFDIR}/libelf.so*)
133     message(STATUS "Libelf is ${LIBELF_LIBRARIES}")
134     message(STATUS "Installing ${LIBELF_INSTALL_FILES} from ${ELFDIR}")
135     install (FILES ${LIBELF_INSTALL_FILES}
136       DESTINATION "${INSTALL_LIB_DIR}")
137   endif()
138   if(NOT LIBDWARF_FOUND)
139     message(STATUS "Installing ${LIBDWARF_LIBRARIES}")
140     install (FILES ${LIBDWARF_LIBRARIES}
141       DESTINATION "${INSTALL_LIB_DIR}")
142   endif()
143 endif()
144 install (FILES
145   "${PROJECT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/DyninstConfig.cmake"
146   "${PROJECT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/DyninstConfigVersion.cmake"
147   DESTINATION "${INSTALL_CMAKE_DIR}")
148 install (EXPORT DyninstTargets
149   DESTINATION "${INSTALL_CMAKE_DIR}")
150 #install(CODE "include(\"${RT_BINARY_DIR}/cmake_install.cmake\")")
151 install(SCRIPT "${RT_BINARY_DIR}/cmake_install.cmake")
152
153 configure_file(cmake/DyninstConfig.cmake.in "${PROJECT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/DyninstConfig.cmake" @ONLY)
154
155 # And version file
156 configure_file(cmake/DyninstConfigVersion.cmake.in "${PROJECT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/DyninstConfigVersion.cmake" @ONLY)