cleanup DyninstRT cmake configuration
[dyninst.git] / CMakeLists.txt
1 cmake_minimum_required (VERSION 2.6.4)
2 project (Dyninst)
3
4 set (DYNINST_ROOT ${PROJECT_SOURCE_DIR})
5 set (CMAKE_SKIP_BUILD_RPATH FALSE)
6 set (CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
7 set (CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
8 LIST(FIND CMAKE_PLATFORM_IMPLICIT_LINK_DIRECTORIES 
9           "${CMAKE_INSTALL_PREFIX}/lib" isSystemDir)
10 IF("${isSystemDir}" STREQUAL "-1")
11                     set (CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib")
12 ENDIF()
13
14 set(RT_SOURCE_DIR ${DYNINST_ROOT}/dyninstAPI_RT)
15 set(RT_BINARY_DIR ${PROJECT_BINARY_DIR}/dyninstAPI_RT)
16
17 include (${DYNINST_ROOT}/cmake/shared.cmake)
18
19 configure_file(cmake/version.h.in common/h/version.h)
20 include_directories(${PROJECT_BINARY_DIR})
21 include_directories(${PROJECT_BINARY_DIR}/common/h)
22 if(${PLATFORM} MATCHES nt)
23   set (HEADER_DIRS common
24     dataflowAPI
25     dyninstAPI
26     dynutil
27     instructionAPI
28     parseAPI
29     patchAPI
30     proccontrol
31     stackwalk
32     symtabAPI
33     )
34 else()
35   set (HEADER_DIRS common
36     dataflowAPI
37     dwarf
38     dyninstAPI
39     dynutil
40     elf
41     instructionAPI
42     parseAPI
43     patchAPI
44     proccontrol
45     stackwalk
46     symlite
47     symtabAPI
48     )
49 endif()
50
51 foreach (dir ${HEADER_DIRS})
52   include_directories ( ${DYNINST_ROOT}/${dir}/h )
53 endforeach()
54
55 include_directories (
56   ${DYNINST_ROOT}
57   ${DYNINST_ROOT}/external
58   )
59 set(Boost_USE_STATIC_LIBS OFF)
60 # Component time
61 add_subdirectory (common)
62 if(NOT ${PLATFORM} MATCHES nt)
63   add_subdirectory (elf)
64   add_subdirectory (dwarf)
65   add_subdirectory (symlite)
66   add_subdirectory (parseThat)
67 # DynC is not compatible with Windows when
68 # we use bison on linux to generate source
69 # TODO: generate with bison configured for
70 # MSVC?
71 if(${SYMREADER} MATCHES symtabAPI)
72   add_subdirectory (dynC_API)
73 endif()
74 endif()
75 add_subdirectory (instructionAPI)
76 add_subdirectory (symtabAPI)
77 add_subdirectory (parseAPI)
78 add_subdirectory (proccontrol)
79 add_subdirectory (stackwalk)
80 add_subdirectory (patchAPI)
81 if(${SYMREADER} MATCHES symtabAPI)
82   add_subdirectory (dyninstAPI)
83 endif()
84
85 if(BUILD_RTLIB)
86   # Build the RT library as a separate project so we can change compilers
87   message(STATUS "Configuring DyninstAPI_RT")
88   file(REMOVE_RECURSE ${RT_BINARY_DIR}/CMakeCache.txt ${RT_BINARY_DIR}/Makefile)
89   file(MAKE_DIRECTORY ${RT_BINARY_DIR})
90   if (PLATFORM MATCHES bgq)
91     set (RT_C_COMPILER mpicc CACHE STRING "Compiler for runtime library")
92   else()
93     set (RT_C_COMPILER ${CMAKE_C_COMPILER} CACHE STRING "Compiler for runtime library")
94   endif()
95   set (ENABLE_STATIC_LIBS NO CACHE STRING "Build static libraries as well?")
96   message(STATUS "Configuring RT library")
97
98   execute_process(WORKING_DIRECTORY ${RT_BINARY_DIR}
99     COMMAND ${CMAKE_COMMAND}
100     -DCMAKE_C_COMPILER=${RT_C_COMPILER}
101     -DCMAKE_BUILD_TYPE=${CMAKE_BUILD_TYPE}
102     -DCMAKE_INSTALL_PREFIX=${CMAKE_INSTALL_PREFIX}
103     -DCMAKE_PREFIX_PATH=${CMAKE_PREFIX_PATH}
104     -DINSTALL_LIB_DIR=${INSTALL_LIB_DIR}
105     -DINSTALL_INCLUDE_DIR=${INSTALL_INCLUDE_DIR}
106     -DCMAKE_C_FLAGS=${CMAKE_C_FLAGS}
107     -DBUILD_RTLIB_32=${BUILD_RTLIB_32}
108     -DPLATFORM=${PLATFORM}
109     -G ${CMAKE_GENERATOR}
110     ${RT_SOURCE_DIR})
111
112   if(MSVC)
113       include_external_msproject(DyninstAPI_RT dyninstAPI_RT/dyninstAPI_RT.vcxproj)
114   else()
115     add_custom_target(DyninstRT
116       ALL
117       $(MAKE)
118       WORKING_DIRECTORY ${RT_BINARY_DIR}
119       COMMENT "Building DyninstRT")
120     add_dependencies(dyninstAPI DyninstRT)
121     if(TARGET dyninstAPI-static)
122       add_dependencies(dyninstAPI-static DyninstRT)
123     endif()
124   endif()
125
126   install(SCRIPT "${RT_BINARY_DIR}/cmake_install.cmake")
127
128 else()
129   message(STATUS "Skipping DyninstAPI_RT. Be sure to build this library if you're using instrumentation.")
130 endif()
131 set (VERSION_STRING "${DYNINST_MAJOR_VERSION}.${DYNINST_MINOR_VERSION}.${DYNINST_PATCH_VERSION}")
132 set (DYNINST_NAME "DyninstAPI-${VERSION_STRING}")
133
134 if(BUILD_TARBALLS)
135   find_package(Git)
136   if(GIT_FOUND)
137     if(EXISTS "${DYNINST_ROOT}/.git/")
138       message(STATUS "Source tree is repository, building archive target")
139       add_custom_target(package ALL)
140       add_custom_command(TARGET package
141         COMMAND ${GIT_EXECUTABLE} archive --prefix="${DYNINST_NAME}/" --format=tar.gz -o "${CMAKE_BINARY_DIR}/${DYNINST_NAME}.tgz" HEAD
142         WORKING_DIRECTORY ${DYNINST_ROOT}
143         COMMENT "Packaging Dyninst")
144     endif()
145   endif()
146 endif()
147 if(BUILD_DOCS)
148   add_custom_target(doc)
149   set(LATEX_DOCS dynC_API dataflowAPI instructionAPI parseAPI patchAPI symtabAPI stackwalk)
150   set(WORD_DOCS proccontrol dyninstAPI)
151   add_custom_target(proccontrol-doc
152     DEPENDS ${CMAKE_SOURCE_DIR}/proccontrol/doc/proccontrol.pdf)
153   add_custom_target(dyninstAPI-doc
154     DEPENDS ${CMAKE_SOURCE_DIR}/dyninstAPI/doc/dyninstAPI.pdf)
155   foreach(COMPONENT ${WORD_DOCS})
156     add_dependencies(doc ${COMPONENT}-doc)
157     set_target_properties(${COMPONENT}-doc PROPERTIES EXCLUDE_FROM_DEFAULT_BUILD 1)
158     install(FILES ${CMAKE_SOURCE_DIR}/${COMPONENT}/doc/${COMPONENT}.pdf
159       DESTINATION ${INSTALL_DOC_DIR}
160       RENAME ${COMPONENT}-${VERSION_STRING}.pdf
161       OPTIONAL
162       )
163   endforeach()
164
165   #set(CMAKE_SKIP_INSTALL_ALL_DEPENDENCY TRUE)
166   find_package(LATEX)
167   if(PDFLATEX_COMPILER)
168     file(COPY ${CMAKE_CURRENT_SOURCE_DIR}/common/doc
169       DESTINATION ${CMAKE_CURRENT_BINARY_DIR}/common)
170     foreach(COMPONENT ${LATEX_DOCS})
171       file(COPY ${CMAKE_CURRENT_SOURCE_DIR}/${COMPONENT}/doc
172         DESTINATION ${CMAKE_CURRENT_BINARY_DIR}/${COMPONENT})
173       set (DEPS "")
174       file(GLOB_RECURSE DEPS ${CMAKE_CURRENT_SOURCE_DIR}/${COMPONENT}/doc/*.tex ${CMAKE_CURRENT_SOURCE_DIR}/common/doc/*.tex)
175       #message(STATUS "Found dependencies for ${COMPONENT} manual: ${DEPS}")
176       add_custom_command(
177         #      OUTPUT ${CMAKE_CURRENT_SOURCE_DIR}/${COMPONENT}/doc/${COMPONENT}.aux
178         OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${COMPONENT}/doc/${COMPONENT}.aux
179         DEPENDS ${DEPS} #${CMAKE_CURRENT_SOURCE_DIR}/${COMPONENT}/doc/${COMPONENT}.tex
180         COMMAND ${PDFLATEX_COMPILER}
181         ARGS -interaction=batchmode ${COMPONENT}.tex
182         WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/${COMPONENT}/doc
183         COMMENT "Latex (first pass)"
184         )
185       add_custom_command(
186         OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${COMPONENT}/doc/${COMPONENT}.log
187         DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${COMPONENT}/doc/${COMPONENT}.aux
188         #      OUTPUT ${CMAKE_CURRENT_SOURCE_DIR}/${COMPONENT}/doc/${COMPONENT}.log
189         #      DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/${COMPONENT}/doc/${COMPONENT}.aux
190         COMMAND ${PDFLATEX_COMPILER}
191         ARGS -interaction=batchmode ${COMPONENT}.tex
192         WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/${COMPONENT}/doc
193         COMMENT "Latex (second pass)"
194         )
195       add_custom_target(${COMPONENT}-doc echo
196         #      DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/${COMPONENT}/doc/${COMPONENT}.log
197         DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${COMPONENT}/doc/${COMPONENT}.log
198         )
199       add_dependencies(doc ${COMPONENT}-doc)
200       set_target_properties(${COMPONENT}-doc PROPERTIES EXCLUDE_FROM_DEFAULT_BUILD 1)
201       #add_dependencies(${COMPONENT} ${COMPONENT}-doc)
202       install(FILES  ${CMAKE_CURRENT_BINARY_DIR}/${COMPONENT}/doc/${COMPONENT}.pdf
203         DESTINATION ${INSTALL_DOC_DIR}
204         RENAME ${COMPONENT}-${VERSION_STRING}.pdf
205         OPTIONAL
206         )
207     endforeach()
208   else()
209     message(STATUS "LaTeX not found")
210   endif()
211 endif()
212
213 if(UNIX)
214   message(STATUS "Adding Unix-specific dependencies")
215   add_dependencies(dynDwarf libdwarf_imp)
216   add_dependencies(dynElf libelf_imp)
217   message(STATUS "Added libdwarf_imp and libelf_imp dependencies")
218   if (NOT USE_GNU_DEMANGLER)
219     add_dependencies(common libiberty_imp)
220   endif()
221   if(NOT LIBDWARF_FOUND)
222     message(STATUS "Building libdwarf, creating libdwarf dependency on libelf")
223     add_dependencies(libdwarf_imp libelf_imp)
224   endif()
225   if(SHOULD_INSTALL_LIBELF)
226     get_filename_component(ELFDIR "${LIBELF_LIBRARIES}" PATH)
227     file(GLOB LIBELF_INSTALL_FILES ${ELFDIR}/libelf.so*)
228     message(STATUS "Libelf is ${LIBELF_LIBRARIES}")
229     message(STATUS "Installing ${LIBELF_INSTALL_FILES} from ${ELFDIR}")
230     install (FILES ${LIBELF_INSTALL_FILES}
231       DESTINATION "${INSTALL_LIB_DIR}")
232   endif()
233   if(NOT LIBDWARF_FOUND)
234     message(STATUS "Installing ${LIBDWARF_LIBRARIES}")
235     install (FILES ${LIBDWARF_LIBRARIES}
236       DESTINATION "${INSTALL_LIB_DIR}")
237   endif()
238 endif()
239