Stopped bottoming target registers of add/sub in some situations.
[dyninst.git] / CMakeLists.txt
1 cmake_minimum_required (VERSION 2.6.4)
2 project (Dyninst)
3
4 set (DYNINST_ROOT ${PROJECT_SOURCE_DIR})
5 set (CMAKE_SKIP_BUILD_RPATH FALSE)
6 set (CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
7 set (CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
8 LIST(FIND CMAKE_PLATFORM_IMPLICIT_LINK_DIRECTORIES 
9           "${CMAKE_INSTALL_PREFIX}/lib" isSystemDir)
10 IF("${isSystemDir}" STREQUAL "-1")
11                     set (CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib")
12 ENDIF()
13
14 set(RT_SOURCE_DIR ${DYNINST_ROOT}/dyninstAPI_RT)
15 set(RT_BINARY_DIR ${PROJECT_BINARY_DIR}/dyninstAPI_RT)
16
17 include (${DYNINST_ROOT}/cmake/shared.cmake)
18
19 configure_file(cmake/version.h.in common/h/version.h)
20 include_directories(${PROJECT_BINARY_DIR})
21 include_directories(${PROJECT_BINARY_DIR}/common/h)
22 if(${PLATFORM} MATCHES nt)
23   set (HEADER_DIRS common
24     dataflowAPI
25     dyninstAPI
26     dynutil
27     instructionAPI
28     parseAPI
29     patchAPI
30     proccontrol
31     stackwalk
32     symtabAPI
33     )
34 else()
35   set (HEADER_DIRS common
36     dataflowAPI
37     dwarf
38     dyninstAPI
39     dynutil
40     elf
41     instructionAPI
42     parseAPI
43     patchAPI
44     proccontrol
45     stackwalk
46     symlite
47     symtabAPI
48     )
49 endif()
50
51 foreach (dir ${HEADER_DIRS})
52   include_directories ( ${DYNINST_ROOT}/${dir}/h )
53 endforeach()
54
55 include_directories (
56   ${DYNINST_ROOT}
57   ${DYNINST_ROOT}/external
58   )
59 set(Boost_USE_STATIC_LIBS OFF)
60 # Component time
61 add_subdirectory (common)
62 if(NOT ${PLATFORM} MATCHES nt)
63   add_subdirectory (elf)
64   add_subdirectory (dwarf)
65   add_subdirectory (symlite)
66 # DynC is not compatible with Windows when
67 # we use bison on linux to generate source
68 # TODO: generate with bison configured for
69 # MSVC?
70 if(${SYMREADER} MATCHES symtabAPI)
71   add_subdirectory (dynC_API)
72 endif()
73 endif()
74 add_subdirectory (instructionAPI)
75 add_subdirectory (symtabAPI)
76 add_subdirectory (parseAPI)
77 add_subdirectory (proccontrol)
78 add_subdirectory (stackwalk)
79 add_subdirectory (patchAPI)
80 if(${SYMREADER} MATCHES symtabAPI)
81   add_subdirectory (dyninstAPI)
82 endif()
83
84 #Build the RT library as a seperate project so we can change compilers
85 message(STATUS "Configuring DyninstAPI_RT")
86 file(REMOVE_RECURSE ${RT_BINARY_DIR}/CMakeCache.txt ${RT_BINARY_DIR}/CMakeFiles ${RT_BINARY_DIR}/Makefile ${RT_BINARY_DIR}/Makefile)
87 file(MAKE_DIRECTORY ${RT_BINARY_DIR})
88 if (PLATFORM MATCHES bgq)
89   set (RT_C_COMPILER mpicc CACHE STRING "Compiler for runtime library")
90 else()
91   set (RT_C_COMPILER ${CMAKE_C_COMPILER} CACHE STRING "Compiler for runtime library")
92 endif()
93 set (NEED_NATIVE_ASSEMBLER NO CACHE STRING "Does the compiler break on assembly files? (Unlikely)")
94 set (ENABLE_STATIC_LIBS NO CACHE STRING "Build static libraries as well?")
95 message(STATUS "Configuring RT library")
96
97 execute_process(WORKING_DIRECTORY ${RT_BINARY_DIR}
98   COMMAND ${CMAKE_COMMAND}
99   -DCMAKE_C_COMPILER=${RT_C_COMPILER}
100   -DCMAKE_BUILD_TYPE=${CMAKE_BUILD_TYPE}
101   -DCMAKE_INSTALL_PREFIX=${CMAKE_INSTALL_PREFIX}
102   -DCMAKE_PREFIX_PATH=${CMAKE_PREFIX_PATH}
103   -DINSTALL_LIB_DIR=${INSTALL_LIB_DIR}
104   -DINSTALL_INCLUDE_DIR=${INSTALL_INCLUDE_DIR}
105   -DCMAKE_C_FLAGS=${CMAKE_C_FLAGS}
106   -DBUILD_RTLIB_32=${BUILD_RTLIB_32}
107   -DNEED_NATIVE_ASSEMBLER=${NEED_NATIVE_ASSEMBLER}
108   -DPLATFORM=${PLATFORM}
109   -G ${CMAKE_GENERATOR}
110   ${RT_SOURCE_DIR})
111
112 add_custom_target(DyninstRT
113   ALL
114   #  COMMAND ${CMAKE_COMMAND} -E chdir ${RT_BINARY_DIR} ${ACTUAL_BUILD}
115   ${CMAKE_BUILD_TOOL}
116   WORKING_DIRECTORY ${RT_BINARY_DIR}
117   COMMENT "Building DyninstRT")
118
119 install(SCRIPT "${RT_BINARY_DIR}/cmake_install.cmake")
120
121 set (VERSION_STRING "${DYNINST_MAJOR_VERSION}.${DYNINST_MINOR_VERSION}.${DYNINST_PATCH_VERSION}")
122 set (DYNINST_NAME "DyninstAPI-${VERSION_STRING}")
123
124 if(BUILD_TARBALLS)
125 find_package(Git)
126 if(GIT_FOUND)
127 if(EXISTS "${DYNINST_ROOT}/.git/")
128 message(STATUS "Source tree is repository, building archive target")
129 add_custom_target(package ALL)
130 add_custom_command(TARGET package
131   COMMAND ${GIT_EXECUTABLE} archive --prefix="${DYNINST_NAME}/" --format=tar.gz -o "${CMAKE_BINARY_DIR}/${DYNINST_NAME}.tgz" HEAD
132   WORKING_DIRECTORY ${DYNINST_ROOT}
133   COMMENT "Packaging Dyninst")
134 endif()
135 endif()
136 endif()
137
138 add_custom_target(doc)
139 set(LATEX_DOCS dynC_API instructionAPI parseAPI patchAPI symtabAPI stackwalk)
140 set(WORD_DOCS proccontrol dyninstAPI)
141 add_custom_target(proccontrol-doc
142   DEPENDS ${CMAKE_SOURCE_DIR}/proccontrol/doc/proccontrol.pdf)
143 add_custom_target(dyninstAPI-doc
144   DEPENDS ${CMAKE_SOURCE_DIR}/dyninstAPI/doc/dyninstAPI.pdf)
145 foreach(COMPONENT ${WORD_DOCS})
146   add_dependencies(doc ${COMPONENT}-doc)
147   install(FILES ${CMAKE_SOURCE_DIR}/${COMPONENT}/doc/${COMPONENT}.pdf
148     DESTINATION ${INSTALL_DOC_DIR}
149     RENAME ${COMPONENT}-${VERSION_STRING}.pdf
150     OPTIONAL
151     )
152 endforeach()
153
154 #set(CMAKE_SKIP_INSTALL_ALL_DEPENDENCY TRUE)
155 find_package(LATEX)
156 if(PDFLATEX_COMPILER)
157   file(COPY ${CMAKE_CURRENT_SOURCE_DIR}/common/doc
158     DESTINATION ${CMAKE_CURRENT_BINARY_DIR}/common)
159   foreach(COMPONENT ${LATEX_DOCS})
160     file(COPY ${CMAKE_CURRENT_SOURCE_DIR}/${COMPONENT}/doc
161       DESTINATION ${CMAKE_CURRENT_BINARY_DIR}/${COMPONENT})
162     set (DEPS "")
163     file(GLOB_RECURSE DEPS ${CMAKE_CURRENT_SOURCE_DIR}/${COMPONENT}/doc/*.tex ${CMAKE_CURRENT_SOURCE_DIR}/common/doc/*.tex)
164     #message(STATUS "Found dependencies for ${COMPONENT} manual: ${DEPS}")
165     add_custom_command(
166       #      OUTPUT ${CMAKE_CURRENT_SOURCE_DIR}/${COMPONENT}/doc/${COMPONENT}.aux
167       OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${COMPONENT}/doc/${COMPONENT}.aux
168       DEPENDS ${DEPS} #${CMAKE_CURRENT_SOURCE_DIR}/${COMPONENT}/doc/${COMPONENT}.tex
169       COMMAND ${PDFLATEX_COMPILER}
170       ARGS -interaction=batchmode ${COMPONENT}.tex
171       WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/${COMPONENT}/doc
172       COMMENT "Latex (first pass)"
173       )
174     add_custom_command(
175       OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${COMPONENT}/doc/${COMPONENT}.log
176       DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${COMPONENT}/doc/${COMPONENT}.aux
177       #      OUTPUT ${CMAKE_CURRENT_SOURCE_DIR}/${COMPONENT}/doc/${COMPONENT}.log
178       #      DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/${COMPONENT}/doc/${COMPONENT}.aux
179       COMMAND ${PDFLATEX_COMPILER}
180       ARGS -interaction=batchmode ${COMPONENT}.tex
181       WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/${COMPONENT}/doc
182       COMMENT "Latex (second pass)"
183       )
184     add_custom_target(${COMPONENT}-doc echo
185       #      DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/${COMPONENT}/doc/${COMPONENT}.log
186       DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${COMPONENT}/doc/${COMPONENT}.log
187       )
188     add_dependencies(doc ${COMPONENT}-doc)
189     #add_dependencies(${COMPONENT} ${COMPONENT}-doc)
190     install(FILES  ${CMAKE_CURRENT_BINARY_DIR}/${COMPONENT}/doc/${COMPONENT}.pdf
191       DESTINATION ${INSTALL_DOC_DIR}
192       RENAME ${COMPONENT}-${VERSION_STRING}.pdf
193       OPTIONAL
194       )
195   endforeach()
196 else()
197   message(STATUS "LaTeX not found")
198 endif()
199
200 if(UNIX)
201   message(STATUS "Adding Unix-specific dependencies")
202   add_dependencies(dynDwarf libdwarf_imp)
203   add_dependencies(dynElf libelf_imp)
204   message(STATUS "Added libdwarf_imp and libelf_imp dependencies")
205   if (NOT USE_GNU_DEMANGLER)
206     add_dependencies(common libiberty_imp)
207   endif()
208   if(NOT LIBDWARF_FOUND)
209     message(STATUS "Building libdwarf, creating libdwarf dependency on libelf")
210     add_dependencies(libdwarf_imp libelf_imp)
211   endif()
212   if(SHOULD_INSTALL_LIBELF)
213     get_filename_component(ELFDIR "${LIBELF_LIBRARIES}" PATH)
214     file(GLOB LIBELF_INSTALL_FILES ${ELFDIR}/libelf.so*)
215     message(STATUS "Libelf is ${LIBELF_LIBRARIES}")
216     message(STATUS "Installing ${LIBELF_INSTALL_FILES} from ${ELFDIR}")
217     install (FILES ${LIBELF_INSTALL_FILES}
218       DESTINATION "${INSTALL_LIB_DIR}")
219   endif()
220   if(NOT LIBDWARF_FOUND)
221     message(STATUS "Installing ${LIBDWARF_LIBRARIES}")
222     install (FILES ${LIBDWARF_LIBRARIES}
223       DESTINATION "${INSTALL_LIB_DIR}")
224   endif()
225 endif()
226